*** empty log message ***

This commit is contained in:
Jim Meyering committed 2001-08-26 07:06:48 +00:00
1 parent a5a086c06e
commit 585aa5fac9
1 file changed
+42
+42
View File
@@ -0,0 +1,42 @@
#serial 1
# autoconf tests required for use of xstrtoimax.c
AC_DEFUN([jm_AC_PREREQ_XSTRTOIMAX],
[
AC_REQUIRE([jm_AC_TYPE_INTMAX_T])
AC_REQUIRE([jm_AC_HEADER_INTTYPES_H])
AC_REQUIRE([jm_AC_TYPE_LONG_LONG])
AC_CHECK_DECLS([strtol, strtoll])
AC_CHECK_HEADERS(limits.h stdlib.h)
AC_CACHE_CHECK([whether <inttypes.h> defines strtoimax as a macro],
jm_cv_func_strtoimax_macro,
AC_EGREP_CPP([inttypes_h_defines_strtoimax], [#include <inttypes.h>
#ifdef strtoimax
inttypes_h_defines_strtoimax
#endif],
jm_cv_func_strtoimax_macro=yes,
jm_cv_func_strtoimax_macro=no))
if test "$jm_cv_func_strtoimax_macro" != yes; then
AC_REPLACE_FUNCS(strtoimax)
fi
dnl We don't need (and can't compile) the replacement strtoll
dnl unless the type `long long' exists.
dnl Also, only the replacement strtoimax invokes strtoll,
dnl so we need the replacement strtoll only if strtoimax does not exist.
case "$ac_cv_type_long_long,$jm_cv_func_strtoimax_macro,$ac_cv_func_strtoimax" in
yes,no,no)
AC_REPLACE_FUNCS(strtoll strtol)
;;
esac
case "$jm_cv_func_strtoimax_macro,$ac_cv_func_strtoimax" in
no,no)
AC_REPLACE_FUNCS(strtoul strtol)
;;
esac
])