mirror of
https://github.com/apache/httpd.git
synced 2025-11-06 16:49:32 +03:00
cd94ba9c69
1) Promoted from "most" to "few" - mod_headers 2) Demoted from "yes" to "most" - mod_actions - mod_allowmethods - mod_auth_form - mod_buffer - mod_cgi(d) - mod_include - mod_negotiation - mod_ratelimit - mod_request - mod_userdir Remember: default module set is "most", but only the LoadModule lines of all modules except "yes" are commented out by default. The following modules will now be loaded by default: - mod_access_compat - mod_alias - mod_auth_basic - mod_authn_core - mod_authn_file - mod_authz_core - mod_authz_groupfile - mod_authz_host - mod_authz_user - mod_autoindex - mod_dir - mod_env - mod_filter - mod_headers - mod_log_config - mod_mime - mod_mpm_event - mod_reqtimeout - mod_setenvif - mod_status - mod_unixd - mod_version git-svn-id: https://svn.apache.org/repos/asf/httpd/httpd/trunk@1201111 13f79535-47bb-0310-9956-ffa450edef68
82 lines
2.8 KiB
Plaintext
82 lines
2.8 KiB
Plaintext
dnl modules enabled in this directory by default
|
|
|
|
dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]])
|
|
|
|
APACHE_MODPATH_INIT(generators)
|
|
|
|
APACHE_MODULE(status, process/thread monitoring, , , yes)
|
|
APACHE_MODULE(autoindex, directory listing, , , yes)
|
|
APACHE_MODULE(asis, as-is filetypes, , , )
|
|
APACHE_MODULE(info, server information, , , most)
|
|
APACHE_MODULE(suexec, set uid and gid for spawned processes, , , no, [
|
|
other_targets=suexec ] )
|
|
|
|
# Is mod_cgid needed?
|
|
case $host in
|
|
*mingw*)
|
|
dnl No fork+thread+fd issues, and cgid doesn't work anyway.
|
|
cgid_needed="no"
|
|
;;
|
|
*)
|
|
if ap_mpm_is_threaded; then
|
|
dnl if we are using a threaded MPM on Unix, we can get better
|
|
dnl performance with mod_cgid, and also avoid potential issues
|
|
dnl with forking from a threaded process.
|
|
cgid_needed="yes"
|
|
else
|
|
dnl if we are using a non-threaded MPM, it makes little sense to
|
|
dnl use mod_cgid, and it just opens up holes we don't need.
|
|
cgid_needed="no"
|
|
fi
|
|
;;
|
|
esac
|
|
|
|
if test $cgid_needed = "yes"; then
|
|
APACHE_MODULE(cgid, CGI scripts. Enabled by default with threaded MPMs, , , most, [
|
|
case $host in
|
|
*-solaris2*)
|
|
case `uname -r` in
|
|
5.10)
|
|
dnl Does the system have the appropriate patches?
|
|
case `uname -p` in
|
|
i386)
|
|
patch_id="120665"
|
|
;;
|
|
sparc)
|
|
patch_id="120664"
|
|
;;
|
|
*)
|
|
AC_MSG_WARN([Unknown platform])
|
|
patch_id="120664"
|
|
;;
|
|
esac
|
|
AC_MSG_CHECKING([for Solaris patch $patch_id])
|
|
showrev -p | grep "$patch_id" >/dev/null 2>&1
|
|
if test $? -eq 1; then
|
|
dnl Solaris 11 (next release) as of snv_19 doesn't have this problem.
|
|
dnl It may be possible to use /kernel/drv/tl from later releases.
|
|
AC_MSG_ERROR([Please apply either patch # 120664 (Sparc) or # 120665 (x86).
|
|
Without these patches, mod_cgid is non-functional on Solaris 10 due to an OS
|
|
bug with AF_UNIX sockets.
|
|
If you can not apply these patches, you can do one of the following:
|
|
- run configure with --disable-cgid
|
|
- switch to the prefork MPM
|
|
For more info: <http://issues.apache.org/bugzilla/show_bug.cgi?id=34264>])
|
|
else
|
|
AC_MSG_RESULT(yes)
|
|
fi
|
|
;;
|
|
esac
|
|
;;
|
|
esac
|
|
])
|
|
APACHE_MODULE(cgi, CGI scripts. Enabled by default with non-threaded MPMs, , , no)
|
|
else
|
|
APACHE_MODULE(cgi, CGI scripts. Enabled by default with non-threaded MPMs, , , most)
|
|
APACHE_MODULE(cgid, CGI scripts. Enabled by default with threaded MPMs, , , no)
|
|
fi
|
|
|
|
APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/$modpath_current])
|
|
|
|
APACHE_MODPATH_FINISH
|