mirror of
https://gitlab.gnome.org/GNOME/libxml2.git
synced 2026-01-26 21:41:34 +03:00
61890e399d
Fix many params in internal functions (not really necessary but Doxygen warns about that in XML mode). Fix formatting in a few corner cases that automatic conversion can't handle. Rearrange some DOC_DISABLE blocks.
24 lines
568 B
Sed
24 lines
568 B
Sed
# Delete function names
|
|
/^ \* (xml|xlink|html)[_[:alnum:]]+:/ d
|
|
|
|
# Escape
|
|
/^ \* /s/#/\\#/g
|
|
|
|
# Convert parameter names
|
|
/^ \* / s/@([_[:alnum:]]+)([^:_[:alnum:]]|$)/`\1`\2/g
|
|
|
|
# Convert parameters and return values
|
|
s/^ \* +@([_[:alnum:]]+):[ ]*/ * @param \1 /
|
|
s/^ \* +[Rr]eturns?[[:>:]]:?/ * @returns/
|
|
|
|
# Convert file headers
|
|
s/^ \* +Summary: *(.*)/ * @brief \1\n * /
|
|
s/^ \* +Description: */ * /
|
|
s/^ \* +Copy:/ * @copyright/
|
|
s/^ \* +Author:/ * @author/
|
|
s/^ \* +DEPRECATED:?/ * @deprecated/
|
|
|
|
# Convert ignored sections
|
|
s/DOC_DISABLE/@cond IGNORE/
|
|
s/DOC_ENABLE/@endcond/
|