mirror of
https://github.com/libssh2/libssh2.git
synced 2025-07-01 11:01:40 +03:00
96d7f404e7
CMake: - Find*: set `<modulename>_FOUND` for compatibility when found via `pkg-config`. E.g. `MbedTLS_FOUND`. `find_package_handle_standard_args()` sets both `<MODULENAME>_FOUND` and `<Modulename>_FOUND` when detecting the dependency. Some CMake code relies on this and 3rd-party code may rely on it too. Make sure to set the latter variant when detecting the dependency via `pkg-config`, where we don't call `find_package_handle_standard_args()`. CMake sets these variable to `TRUE` (not `ON` or `1`). Replicate this for compatibility. - libssh2-config.cmake: inherit default `LIBSSH2_USE_PKGCONFIG`. Follow-up toa3aa6b4ca8#1525 - document variables consumed by `libssh2-config.cmake.in`. - `libssh2-config.cmake`: fix to link to non-OpenSSL crypto backends. This is most likely not how this is supposed to be done, but better than failing. What's the canonical way to do this, and how OpenSSL and zlib does it is yet to be figured out. - use `ZLIB::ZLIB` to reference zlib. - use `IN ITEMS` where missed. - harmonize variable dump output formats. CMake `find_package` integration tests: - extend to all crypto backends (was: OpenSSL). - show libssh2 variables set by `find_package()`. - stop building examples and tests for the consumed package. For performance. - enable zlib, for coverage. - be verbose when building the test targets. ci/GHA: - add packaged mbedTLS (2.x) build to Linux matrix. - alphasort some tests. Follow-up tod9c2e550ca#1460 Follow-up to82b09f9b3a#1322 Closes #1534
65 lines
2.2 KiB
CMake
65 lines
2.2 KiB
CMake
# Copyright (C) The libssh2 project and its contributors.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
#
|
|
###########################################################################
|
|
# Find the Libgcrypt library
|
|
#
|
|
# Input variables:
|
|
#
|
|
# - `LIBGCRYPT_INCLUDE_DIR`: The Libgcrypt include directory.
|
|
# - `LIBGCRYPT_LIBRARY`: Path to `libgcrypt` library.
|
|
#
|
|
# Result variables:
|
|
#
|
|
# - `LIBGCRYPT_FOUND`: System has Libgcrypt.
|
|
# - `LIBGCRYPT_INCLUDE_DIRS`: The Libgcrypt include directories.
|
|
# - `LIBGCRYPT_LIBRARIES`: The Libgcrypt library names.
|
|
# - `LIBGCRYPT_LIBRARY_DIRS`: The Libgcrypt library directories.
|
|
# - `LIBGCRYPT_PC_REQUIRES`: The Libgcrypt pkg-config packages.
|
|
# - `LIBGCRYPT_CFLAGS`: Required compiler flags.
|
|
# - `LIBGCRYPT_VERSION`: Version of Libgcrypt.
|
|
|
|
set(LIBGCRYPT_PC_REQUIRES "libgcrypt")
|
|
|
|
if(LIBSSH2_USE_PKGCONFIG AND
|
|
NOT DEFINED LIBGCRYPT_INCLUDE_DIR AND
|
|
NOT DEFINED LIBGCRYPT_LIBRARY)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(LIBGCRYPT ${LIBGCRYPT_PC_REQUIRES})
|
|
endif()
|
|
|
|
if(LIBGCRYPT_FOUND)
|
|
set(Libgcrypt_FOUND TRUE)
|
|
string(REPLACE ";" " " LIBGCRYPT_CFLAGS "${LIBGCRYPT_CFLAGS}")
|
|
message(STATUS "Found Libgcrypt (via pkg-config): ${LIBGCRYPT_INCLUDE_DIRS} (found version \"${LIBGCRYPT_VERSION}\")")
|
|
else()
|
|
find_path(LIBGCRYPT_INCLUDE_DIR NAMES "gcrypt.h")
|
|
find_library(LIBGCRYPT_LIBRARY NAMES "gcrypt" "libgcrypt")
|
|
|
|
unset(LIBGCRYPT_VERSION CACHE)
|
|
if(LIBGCRYPT_INCLUDE_DIR AND EXISTS "${LIBGCRYPT_INCLUDE_DIR}/gcrypt.h")
|
|
set(_version_regex "#[\t ]*define[\t ]+GCRYPT_VERSION[\t ]+\"([^\"]*)\"")
|
|
file(STRINGS "${LIBGCRYPT_INCLUDE_DIR}/gcrypt.h" _version_str REGEX "${_version_regex}")
|
|
string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
|
|
set(LIBGCRYPT_VERSION "${_version_str}")
|
|
unset(_version_regex)
|
|
unset(_version_str)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(Libgcrypt
|
|
REQUIRED_VARS
|
|
LIBGCRYPT_INCLUDE_DIR
|
|
LIBGCRYPT_LIBRARY
|
|
VERSION_VAR
|
|
LIBGCRYPT_VERSION
|
|
)
|
|
|
|
if(LIBGCRYPT_FOUND)
|
|
set(LIBGCRYPT_INCLUDE_DIRS ${LIBGCRYPT_INCLUDE_DIR})
|
|
set(LIBGCRYPT_LIBRARIES ${LIBGCRYPT_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(LIBGCRYPT_INCLUDE_DIR LIBGCRYPT_LIBRARY)
|
|
endif()
|