mirror of
https://github.com/libssh2/libssh2.git
synced 2026-10-24 03:48:58 +03:00
8d4bd82c26
Silencing:
```
/bin/bash: ..//config.rpath: No such file or directory
checking for shared library run path origin... done
```
Reported-by: Rainer Jung
Fixes #2149
Follow-up to 0443145a75 #1920
Closes #2150
275 lines
10 KiB
Plaintext
275 lines
10 KiB
Plaintext
# lib-link.m4 serial 13 (gettext-0.16.2)
|
|
dnl Copyright (C) 2001-2007 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
dnl
|
|
dnl SPDX-License-Identifier: FSFULLR
|
|
|
|
dnl From Bruno Haible.
|
|
|
|
AC_PREREQ([2.54])
|
|
|
|
dnl LIBSSH2_WITH_FINAL_PREFIX([statement]) evaluates statement, with the
|
|
dnl variables prefix and exec_prefix bound to the values they have
|
|
dnl at the end of the configure script.
|
|
AC_DEFUN([LIBSSH2_WITH_FINAL_PREFIX],
|
|
[
|
|
acl_save_prefix="$prefix"
|
|
prefix="$acl_final_prefix"
|
|
acl_save_exec_prefix="$exec_prefix"
|
|
exec_prefix="$acl_final_exec_prefix"
|
|
$1
|
|
exec_prefix="$acl_save_exec_prefix"
|
|
prefix="$acl_save_prefix"
|
|
])
|
|
|
|
dnl LIBSSH2_PREPARE_PREFIX creates variables acl_final_prefix,
|
|
dnl acl_final_exec_prefix, containing the values to which $prefix and
|
|
dnl $exec_prefix expands at the end of the configure script.
|
|
AC_DEFUN([LIBSSH2_PREPARE_PREFIX],
|
|
[
|
|
dnl Unfortunately, prefix and exec_prefix get only finally determined
|
|
dnl at the end of configure.
|
|
if test "X$prefix" = "XNONE"; then
|
|
acl_final_prefix="$ac_default_prefix"
|
|
else
|
|
acl_final_prefix="$prefix"
|
|
fi
|
|
if test "X$exec_prefix" = "XNONE"; then
|
|
acl_final_exec_prefix='${prefix}'
|
|
else
|
|
acl_final_exec_prefix="$exec_prefix"
|
|
fi
|
|
acl_save_prefix="$prefix"
|
|
prefix="$acl_final_prefix"
|
|
eval acl_final_exec_prefix=\"$acl_final_exec_prefix\"
|
|
prefix="$acl_save_prefix"
|
|
])
|
|
|
|
dnl LIBSSH2_PREPARE_MULTILIB creates a variable acl_libdirstem, containing
|
|
dnl the basename of the libdir, either "lib" or "lib64".
|
|
AC_DEFUN([LIBSSH2_PREPARE_MULTILIB],
|
|
[
|
|
dnl There is no formal standard regarding lib and lib64. The current
|
|
dnl practice is that on a system supporting 32-bit and 64-bit instruction
|
|
dnl sets or ABIs, 64-bit libraries go under $prefix/lib64 and 32-bit
|
|
dnl libraries go under $prefix/lib. We determine the compiler's default
|
|
dnl mode by looking at the compiler's library search path. If at least
|
|
dnl of its elements ends in /lib64 or points to a directory whose absolute
|
|
dnl pathname ends in /lib64, we assume a 64-bit ABI. Otherwise we use the
|
|
dnl default, namely "lib".
|
|
acl_libdirstem=lib
|
|
searchpath=`(LC_ALL=C $CC -print-search-dirs) 2>/dev/null | sed -n -e 's,^libraries: ,,p' | sed -e 's,^=,,'`
|
|
if test -n "$searchpath"; then
|
|
acl_save_IFS="${IFS= }"; IFS=":"
|
|
for searchdir in $searchpath; do
|
|
if test -d "$searchdir"; then
|
|
case "$searchdir" in
|
|
*/lib64/ | */lib64 ) acl_libdirstem=lib64 ;;
|
|
*) searchdir=`cd "$searchdir" && pwd`
|
|
case "$searchdir" in
|
|
*/lib64 ) acl_libdirstem=lib64 ;;
|
|
esac ;;
|
|
esac
|
|
fi
|
|
done
|
|
IFS="$acl_save_IFS"
|
|
fi
|
|
])
|
|
|
|
dnl LIBSSH2_LINKFLAGS(name [, dependencies]) searches for libname and
|
|
dnl the libraries corresponding to explicit and implicit dependencies.
|
|
dnl Sets and AC_SUBSTs the LIB${NAME} and LTLIB${NAME} variables and
|
|
dnl augments the CPPFLAGS variable.
|
|
dnl Sets and AC_SUBSTs the LIB${NAME}_PREFIX variable to nonempty if libname
|
|
dnl was found in ${LIB${NAME}_PREFIX}/$acl_libdirstem.
|
|
AC_DEFUN([LIBSSH2_LINKFLAGS],
|
|
[
|
|
AC_REQUIRE([LIBSSH2_PREPARE_PREFIX])
|
|
define([Name],[translit([$1],[./-], [___])])
|
|
define([NAME],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
|
|
[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
|
|
AC_CACHE_CHECK([how to link with lib[]$1], [ac_cv_lib[]Name[]_libs], [
|
|
LIBSSH2_LINKFLAGS_BODY([$1], [$2])
|
|
ac_cv_lib[]Name[]_libs="$LIB[]NAME"
|
|
ac_cv_lib[]Name[]_ltlibs="$LTLIB[]NAME"
|
|
ac_cv_lib[]Name[]_cppflags="$INC[]NAME"
|
|
ac_cv_lib[]Name[]_prefix="$LIB[]NAME[]_PREFIX"
|
|
])
|
|
LIB[]NAME="$ac_cv_lib[]Name[]_libs"
|
|
LTLIB[]NAME="$ac_cv_lib[]Name[]_ltlibs"
|
|
INC[]NAME="$ac_cv_lib[]Name[]_cppflags"
|
|
LIB[]NAME[]_PREFIX="$ac_cv_lib[]Name[]_prefix"
|
|
LIBSSH2_APPENDTOVAR([CPPFLAGS], [$INC]NAME)
|
|
AC_SUBST([LIB]NAME)
|
|
AC_SUBST([LTLIB]NAME)
|
|
AC_SUBST([LIB]NAME[_PREFIX])
|
|
dnl Also set HAVE_LIB[]NAME so that LIBSSH2_HAVE_LINKFLAGS can reuse the
|
|
dnl results of this search when this library appears as a dependency.
|
|
HAVE_LIB[]NAME=yes
|
|
undefine([Name])
|
|
undefine([NAME])
|
|
])
|
|
|
|
dnl LIBSSH2_HAVE_LINKFLAGS(name, dependencies, includes, testcode)
|
|
dnl searches for libname and the libraries corresponding to explicit and
|
|
dnl implicit dependencies, together with the specified include files and
|
|
dnl the ability to compile and link the specified testcode. If found, it
|
|
dnl sets and AC_SUBSTs HAVE_LIB${NAME}=yes and the LIB${NAME} and
|
|
dnl LTLIB${NAME} variables and augments the CPPFLAGS variable, and
|
|
dnl #defines HAVE_LIB${NAME} to 1. Otherwise, it sets and AC_SUBSTs
|
|
dnl HAVE_LIB${NAME}=no and LIB${NAME} and LTLIB${NAME} to empty.
|
|
dnl Sets and AC_SUBSTs the LIB${NAME}_PREFIX variable to nonempty if libname
|
|
dnl was found in ${LIB${NAME}_PREFIX}/$acl_libdirstem.
|
|
AC_DEFUN([LIBSSH2_HAVE_LINKFLAGS],
|
|
[
|
|
AC_REQUIRE([LIBSSH2_PREPARE_PREFIX])
|
|
define([Name],[translit([$1],[./-], [___])])
|
|
define([NAME],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
|
|
[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
|
|
|
|
dnl Search for lib[]Name and define LIB[]NAME, LTLIB[]NAME and INC[]NAME
|
|
dnl accordingly.
|
|
LIBSSH2_LINKFLAGS_BODY([$1], [$2])
|
|
|
|
dnl Add $INC[]NAME to CPPFLAGS before performing the following checks,
|
|
dnl because if the user has installed lib[]Name and not disabled its use
|
|
dnl via --without-lib[]Name-prefix, he wants to use it.
|
|
ac_save_CPPFLAGS="$CPPFLAGS"
|
|
LIBSSH2_APPENDTOVAR([CPPFLAGS], [$INC]NAME)
|
|
|
|
AC_CACHE_CHECK([for lib[]$1], [ac_cv_lib[]Name], [
|
|
ac_save_LIBS="$LIBS"
|
|
LIBS="$LIBS $LIB[]NAME"
|
|
AC_LINK_IFELSE([AC_LANG_PROGRAM([[$3]], [[$4]])],[ac_cv_lib[]Name=yes],[ac_cv_lib[]Name=no])
|
|
LIBS="$ac_save_LIBS"
|
|
])
|
|
if test "$ac_cv_lib[]Name" = yes; then
|
|
HAVE_LIB[]NAME=yes
|
|
AC_DEFINE([HAVE_LIB]NAME, 1, [Define if you have the $1 library.])
|
|
AC_MSG_CHECKING([how to link with lib[]$1])
|
|
AC_MSG_RESULT([$LIB[]NAME])
|
|
else
|
|
HAVE_LIB[]NAME=no
|
|
dnl If $LIB[]NAME did not lead to a usable library, we do not need
|
|
dnl $INC[]NAME either.
|
|
CPPFLAGS="$ac_save_CPPFLAGS"
|
|
LIB[]NAME=
|
|
LTLIB[]NAME=
|
|
LIB[]NAME[]_PREFIX=
|
|
fi
|
|
AC_SUBST([HAVE_LIB]NAME)
|
|
AC_SUBST([LIB]NAME)
|
|
AC_SUBST([LTLIB]NAME)
|
|
AC_SUBST([LIB]NAME[_PREFIX])
|
|
undefine([Name])
|
|
undefine([NAME])
|
|
])
|
|
|
|
dnl LIBSSH2_LINKFLAGS_BODY(name [, dependencies]) searches for libname and
|
|
dnl the libraries corresponding to explicit and implicit dependencies.
|
|
dnl Sets the LIB${NAME}, LTLIB${NAME} and INC${NAME} variables.
|
|
dnl Also, sets the LIB${NAME}_PREFIX variable to nonempty if libname was found
|
|
dnl in ${LIB${NAME}_PREFIX}/$acl_libdirstem.
|
|
AC_DEFUN([LIBSSH2_LINKFLAGS_BODY],
|
|
[
|
|
AC_REQUIRE([LIBSSH2_PREPARE_MULTILIB])
|
|
define([NAME],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
|
|
[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
|
|
dnl Autoconf >= 2.61 supports dots in --with options.
|
|
define([N_A_M_E],[m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]),[2.61]),[-1],[translit([$1],[.],[_])],[$1])])
|
|
dnl By default, look in $includedir and $libdir.
|
|
use_additional=yes
|
|
LIBSSH2_WITH_FINAL_PREFIX([
|
|
eval additional_includedir=\"$includedir\"
|
|
eval additional_libdir=\"$libdir\"
|
|
])
|
|
AC_ARG_WITH([lib]N_A_M_E[-prefix],
|
|
[ --with-lib]N_A_M_E[-prefix[=DIR] search for lib$1 in DIR/include and DIR/lib
|
|
--without-lib]N_A_M_E[-prefix do not search for lib$1 in includedir and libdir],
|
|
[
|
|
if test "X$withval" = "Xno"; then
|
|
use_additional=no
|
|
else
|
|
if test "X$withval" = "X"; then
|
|
LIBSSH2_WITH_FINAL_PREFIX([
|
|
eval additional_includedir=\"$includedir\"
|
|
eval additional_libdir=\"$libdir\"
|
|
])
|
|
else
|
|
additional_includedir="$withval/include"
|
|
additional_libdir="$withval/$acl_libdirstem"
|
|
fi
|
|
fi
|
|
])
|
|
dnl Search the library and its dependencies in $additional_libdir and
|
|
dnl $LDFLAGS. Using breadth-first-seach.
|
|
LIB[]NAME=
|
|
LTLIB[]NAME=
|
|
INC[]NAME=
|
|
LIB[]NAME[]_PREFIX=
|
|
names_already_handled=
|
|
names_next_round='$1 $2'
|
|
while test -n "$names_next_round"; do
|
|
names_this_round="$names_next_round"
|
|
names_next_round=
|
|
for name in $names_this_round; do
|
|
already_handled=
|
|
for n in $names_already_handled; do
|
|
if test "$n" = "$name"; then
|
|
already_handled=yes
|
|
break
|
|
fi
|
|
done
|
|
if test -z "$already_handled"; then
|
|
names_already_handled="$names_already_handled $name"
|
|
dnl See if it was already located by an earlier LIBSSH2_LINKFLAGS
|
|
dnl or LIBSSH2_HAVE_LINKFLAGS call.
|
|
uppername=`echo "$name" | sed -e 'y|abcdefghijklmnopqrstuvwxyz./-|ABCDEFGHIJKLMNOPQRSTUVWXYZ___|'`
|
|
eval value=\"\$HAVE_LIB$uppername\"
|
|
if test -n "$value"; then
|
|
if test "$value" = yes; then
|
|
eval value=\"\$LIB$uppername\"
|
|
test -z "$value" || LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$value"
|
|
eval value=\"\$LTLIB$uppername\"
|
|
test -z "$value" || LTLIB[]NAME="${LTLIB[]NAME}${LTLIB[]NAME:+ }$value"
|
|
else
|
|
dnl An earlier call to LIBSSH2_HAVE_LINKFLAGS has determined
|
|
dnl that this library does not exist. So drop it.
|
|
:
|
|
fi
|
|
else
|
|
dnl Did not find the library; assume it is in the system directories
|
|
dnl known to the linker and runtime loader. (All the system
|
|
dnl directories known to the linker should also be known to the
|
|
dnl runtime loader, otherwise the system is severely misconfigured.)
|
|
LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }-l$name"
|
|
LTLIB[]NAME="${LTLIB[]NAME}${LTLIB[]NAME:+ }-l$name"
|
|
fi
|
|
fi
|
|
done
|
|
done
|
|
])
|
|
|
|
dnl LIBSSH2_APPENDTOVAR(VAR, CONTENTS) appends the elements of CONTENTS to VAR,
|
|
dnl unless already present in VAR.
|
|
dnl Works only for CPPFLAGS, not for LIB* variables because that sometimes
|
|
dnl contains two or three consecutive elements that belong together.
|
|
AC_DEFUN([LIBSSH2_APPENDTOVAR],
|
|
[
|
|
for element in [$2]; do
|
|
haveit=
|
|
for x in $[$1]; do
|
|
LIBSSH2_WITH_FINAL_PREFIX([eval x=\"$x\"])
|
|
if test "X$x" = "X$element"; then
|
|
haveit=yes
|
|
break
|
|
fi
|
|
done
|
|
if test -z "$haveit"; then
|
|
[$1]="${[$1]}${[$1]:+ }$element"
|
|
fi
|
|
done
|
|
])
|