mirror of
https://github.com/libssh2/libssh2.git
synced 2026-10-24 03:48:58 +03:00
86dcc0ae40
After limiting `find_package()`/`find_dependency()` calls to libssh2 local Find modules via the `MODULES` keyword, it became possible to detect dependencies via CMake Configs from within those local Find modules, by calling `find_package()` again with the `CONFIG` keyword. This patch implements this. Then maps detection results to the result variables and libssh2-specific imported targets the rest of the build expects. This adds CMake Configs as an alternative to the existing `pkg-config` and `find_path()`/`find_library()` auto-detection methods. Enabled by default for MSVC, outside vcpkg and when not cross-building. To enable for other cases, or override the default, you can use `-DLIBSSH2_USE_CMAKECONFIG=ON` or `OFF`. When enabled, Config detection happens after `pkg-config` and before `find_path()`/`find_library()`. Using CMake's built-in options, you may also manually point to the absolute directory holding Config files: `MbedTLS_DIR`, `wolfssl_DIR` E.g. `-DMbedTLS_DIR=/path/to/mbedtls/lib/cmake/MbedTLS` mbedTLS needs to be built with CMake for this to work. wolfSSL 5.9.0+ also supports it when it was built with autotools. Experimental. Refs:8fce3e17e6https://github.com/curl/curl/pull/20814a56ab9dbc8https://github.com/curl/curl/pull/21098 Follow-up todd5f3fff39#2262 Closes #2264
108 lines
3.6 KiB
CMake
108 lines
3.6 KiB
CMake
# Copyright (C) The libssh2 project and its contributors.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
#
|
|
###########################################################################
|
|
# Find the wolfSSL library
|
|
#
|
|
# Input variables:
|
|
#
|
|
# - `WOLFSSL_INCLUDE_DIR`: Absolute path to wolfSSL include directory.
|
|
# - `WOLFSSL_LIBRARY`: Absolute path to `wolfssl` library.
|
|
#
|
|
# Defines:
|
|
#
|
|
# - `WOLFSSL_FOUND`: System has wolfSSL.
|
|
# - `WOLFSSL_VERSION`: Version of wolfSSL.
|
|
# - `libssh2::wolfssl`: wolfssl library target.
|
|
|
|
set(_wolfssl_pc_requires "wolfssl")
|
|
|
|
if(NOT DEFINED WOLFSSL_INCLUDE_DIR AND
|
|
NOT DEFINED WOLFSSL_LIBRARY)
|
|
if(LIBSSH2_USE_PKGCONFIG)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(_wolfssl ${_wolfssl_pc_requires})
|
|
endif()
|
|
if(NOT _wolfssl_FOUND AND LIBSSH2_USE_CMAKECONFIG)
|
|
find_package(wolfssl CONFIG QUIET)
|
|
endif()
|
|
endif()
|
|
|
|
if(_wolfssl_FOUND)
|
|
set(WolfSSL_FOUND TRUE)
|
|
set(WOLFSSL_FOUND TRUE)
|
|
set(WOLFSSL_VERSION ${_wolfssl_VERSION})
|
|
message(STATUS "Found WolfSSL (via pkg-config): ${_wolfssl_INCLUDE_DIRS} (found version \"${WOLFSSL_VERSION}\")")
|
|
elseif(wolfssl_CONFIG)
|
|
set(WolfSSL_FOUND TRUE)
|
|
set(WOLFSSL_FOUND TRUE)
|
|
set(WOLFSSL_VERSION ${wolfssl_VERSION})
|
|
set(_wolfssl_LIBRARIES wolfssl::wolfssl)
|
|
message(STATUS "Found WolfSSL (via CMake Config): ${wolfssl_CONFIG} (found version \"${WOLFSSL_VERSION}\")")
|
|
else()
|
|
find_path(WOLFSSL_INCLUDE_DIR NAMES "wolfssl/options.h")
|
|
find_library(WOLFSSL_LIBRARY NAMES "wolfssl")
|
|
|
|
unset(WOLFSSL_VERSION CACHE)
|
|
if(WOLFSSL_INCLUDE_DIR AND EXISTS "${WOLFSSL_INCLUDE_DIR}/wolfssl/version.h")
|
|
set(_version_regex "#[\t ]*define[\t ]+LIBWOLFSSL_VERSION_STRING[\t ]+\"([^\"]*)\"")
|
|
file(STRINGS "${WOLFSSL_INCLUDE_DIR}/wolfssl/version.h" _version_str REGEX "${_version_regex}")
|
|
string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
|
|
set(WOLFSSL_VERSION "${_version_str}")
|
|
unset(_version_regex)
|
|
unset(_version_str)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WolfSSL
|
|
REQUIRED_VARS
|
|
WOLFSSL_INCLUDE_DIR
|
|
WOLFSSL_LIBRARY
|
|
VERSION_VAR
|
|
WOLFSSL_VERSION
|
|
)
|
|
|
|
if(WOLFSSL_FOUND)
|
|
set(_wolfssl_INCLUDE_DIRS ${WOLFSSL_INCLUDE_DIR})
|
|
set(_wolfssl_LIBRARIES ${WOLFSSL_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(WOLFSSL_INCLUDE_DIR WOLFSSL_LIBRARY)
|
|
endif()
|
|
|
|
if(WOLFSSL_FOUND)
|
|
if(APPLE)
|
|
find_library(SECURITY_FRAMEWORK NAMES "Security")
|
|
mark_as_advanced(SECURITY_FRAMEWORK)
|
|
if(NOT SECURITY_FRAMEWORK)
|
|
message(FATAL_ERROR "Security framework not found")
|
|
endif()
|
|
list(APPEND _wolfssl_LIBRARIES "-framework Security")
|
|
|
|
find_library(COREFOUNDATION_FRAMEWORK NAMES "CoreFoundation")
|
|
mark_as_advanced(COREFOUNDATION_FRAMEWORK)
|
|
if(NOT COREFOUNDATION_FRAMEWORK)
|
|
message(FATAL_ERROR "CoreFoundation framework not found")
|
|
endif()
|
|
list(APPEND _wolfssl_LIBRARIES "-framework CoreFoundation")
|
|
elseif(WIN32)
|
|
list(APPEND _wolfssl_LIBRARIES "crypt32")
|
|
else()
|
|
find_library(MATH_LIBRARY NAMES "m")
|
|
if(MATH_LIBRARY)
|
|
list(APPEND _wolfssl_LIBRARIES ${MATH_LIBRARY}) # for log and pow
|
|
endif()
|
|
mark_as_advanced(MATH_LIBRARY)
|
|
endif()
|
|
|
|
if(NOT TARGET libssh2::wolfssl)
|
|
add_library(libssh2::wolfssl INTERFACE IMPORTED)
|
|
set_target_properties(libssh2::wolfssl PROPERTIES
|
|
INTERFACE_LIBSSH2_PC_MODULES "${_wolfssl_pc_requires}"
|
|
INTERFACE_COMPILE_OPTIONS "${_wolfssl_CFLAGS}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${_wolfssl_INCLUDE_DIRS}"
|
|
INTERFACE_LINK_DIRECTORIES "${_wolfssl_LIBRARY_DIRS}"
|
|
INTERFACE_LINK_LIBRARIES "${_wolfssl_LIBRARIES}")
|
|
endif()
|
|
endif()
|