mirror of
https://git.savannah.gnu.org/git/gnulib.git
synced 2025-08-17 12:41:05 +03:00
127cc81588
* lib/utime.in.h: Include next <utime.h> if it exists. (utimbuf): Define to _utimbuf on native Windows. * m4/utime-h.m4 (gl_UTIME_H): Check for prerequisites of include_next. Set UTIME_H on native Windows. (gl_UTIME_MODULE_INDICATOR, gl_HEADER_UTIME_H_DEFAULTS): New macros. * modules/utime-h (Depends-on): Add include_next. (Makefile.am): Substitute also HAVE_UTIME_H, INCLUDE_NEXT, PRAGMA_SYSTEM_HEADER, PRAGMA_COLUMNS, NEXT_UTIME_H. * lib/utimens.c (utimbuf): Remove fallback definition. * m4/utimens.m4 (gl_UTIMENS): Don't require gl_CHECK_TYPE_STRUCT_UTIMBUF. * m4/utimbuf.m4: Remove file. * modules/utimens (Files): Remove m4/utimbuf.m4.
50 lines
1.7 KiB
Plaintext
50 lines
1.7 KiB
Plaintext
dnl Copyright (C) 2003-2017 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl serial 8
|
|
|
|
AC_DEFUN([gl_UTIMENS],
|
|
[
|
|
dnl Prerequisites of lib/utimens.c.
|
|
AC_REQUIRE([gl_FUNC_UTIMES])
|
|
AC_REQUIRE([gl_CHECK_TYPE_STRUCT_TIMESPEC])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
AC_CHECK_FUNCS_ONCE([futimes futimesat futimens utimensat lutimes])
|
|
|
|
if test $ac_cv_func_futimens = no && test $ac_cv_func_futimesat = yes; then
|
|
dnl FreeBSD 8.0-rc2 mishandles futimesat(fd,NULL,time). It is not
|
|
dnl standardized, but Solaris implemented it first and uses it as
|
|
dnl its only means to set fd time.
|
|
AC_CACHE_CHECK([whether futimesat handles NULL file],
|
|
[gl_cv_func_futimesat_works],
|
|
[touch conftest.file
|
|
AC_RUN_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <stddef.h>
|
|
#include <sys/times.h>
|
|
#include <fcntl.h>
|
|
]], [[ int fd = open ("conftest.file", O_RDWR);
|
|
if (fd < 0) return 1;
|
|
if (futimesat (fd, NULL, NULL)) return 2;
|
|
]])],
|
|
[gl_cv_func_futimesat_works=yes],
|
|
[gl_cv_func_futimesat_works=no],
|
|
[case "$host_os" in
|
|
# Guess yes on glibc systems.
|
|
*-gnu*) gl_cv_func_futimesat_works="guessing yes" ;;
|
|
# If we don't know, assume the worst.
|
|
*) gl_cv_func_futimesat_works="guessing no" ;;
|
|
esac
|
|
])
|
|
rm -f conftest.file])
|
|
case "$gl_cv_func_futimesat_works" in
|
|
*yes) ;;
|
|
*)
|
|
AC_DEFINE([FUTIMESAT_NULL_BUG], [1],
|
|
[Define to 1 if futimesat mishandles a NULL file name.])
|
|
;;
|
|
esac
|
|
fi
|
|
])
|