mirror of
https://git.savannah.gnu.org/git/gnulib.git
synced 2025-08-16 01:22:18 +03:00
The rationale is: 1) Read-preferring read-write locks are prone to writer starvation if the number of reader threads multiplied by the percentage of time they have the lock held is too high. 2) Write- preferring read-write locks are the only reliable way to avoid this. 3) There have been reports of 'test-lock' hanging on glibc systems http://lists.gnu.org/archive/html/bug-gnulib/2017-01/msg00009.html, and glibc indeed implements read-preferring rwlocks by default, see http://man7.org/linux/man-pages/man3/pthread_rwlockattr_setkind_np.3.html and https://sourceware.org/bugzilla/show_bug.cgi?id=13701 . * m4/pthread_rwlock_rdlock.m4: New file. * m4/lock.m4 (gl_LOCK): Invoke gl_PTHREAD_RWLOCK_RDLOCK_PREFER_WRITER. * lib/glthread/lock.h [USE_POSIX_THREADS]: Test HAVE_PTHREAD_RWLOCK_RDLOCK_PREFER_WRITER. Use a different implementation of rwlock initialization on glibc systems without HAVE_PTHREAD_RWLOCK_RDLOCK_PREFER_WRITER. Use a different implementation of rwlocks altogether on non-glibc systems without HAVE_PTHREAD_RWLOCK_RDLOCK_PREFER_WRITER. [USE_PTH_THREADS]: Use a different implementation of rwlocks altogether. * lib/glthread/lock.c [USE_POSIX_THREADS] (glthread_rwlock_init_for_glibc): New function. [USE_POSIX_THREADS] (glthread_rwlock_rdlock_multithreaded): Update comment. [USE_PTH_THREADS]: New implementation of rwlocks. [USE_WINDOWS_THREADS] (glthread_rwlock_rdlock_func): Prefer writers over readers. * modules/lock (Files): Add m4/pthread_rwlock_rdlock.m4. (Depends-on): Add 'extensions'. * tests/test-rwlock1.c: New file. * lock-tests (Files): Add it. (Depends-on): Add usleep. (Makefile.am): Add test-rwlock1 to the tests.
48 lines
1.5 KiB
Plaintext
48 lines
1.5 KiB
Plaintext
# lock.m4 serial 14
|
|
dnl Copyright (C) 2005-2017 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Bruno Haible.
|
|
|
|
AC_DEFUN([gl_LOCK],
|
|
[
|
|
AC_REQUIRE([gl_THREADLIB])
|
|
if test "$gl_threads_api" = posix; then
|
|
# OSF/1 4.0 and Mac OS X 10.1 lack the pthread_rwlock_t type and the
|
|
# pthread_rwlock_* functions.
|
|
has_rwlock=false
|
|
AC_CHECK_TYPE([pthread_rwlock_t],
|
|
[has_rwlock=true
|
|
AC_DEFINE([HAVE_PTHREAD_RWLOCK], [1],
|
|
[Define if the POSIX multithreading library has read/write locks.])],
|
|
[],
|
|
[#include <pthread.h>])
|
|
if $has_rwlock; then
|
|
gl_PTHREAD_RWLOCK_RDLOCK_PREFER_WRITER
|
|
fi
|
|
# glibc defines PTHREAD_MUTEX_RECURSIVE as enum, not as a macro.
|
|
AC_COMPILE_IFELSE([
|
|
AC_LANG_PROGRAM(
|
|
[[#include <pthread.h>]],
|
|
[[
|
|
#if __FreeBSD__ == 4
|
|
error "No, in FreeBSD 4.0 recursive mutexes actually don't work."
|
|
#elif (defined __ENVIRONMENT_MAC_OS_X_VERSION_MIN_REQUIRED__ \
|
|
&& __ENVIRONMENT_MAC_OS_X_VERSION_MIN_REQUIRED__ < 1070)
|
|
error "No, in Mac OS X < 10.7 recursive mutexes actually don't work."
|
|
#else
|
|
int x = (int)PTHREAD_MUTEX_RECURSIVE;
|
|
return !x;
|
|
#endif
|
|
]])],
|
|
[AC_DEFINE([HAVE_PTHREAD_MUTEX_RECURSIVE], [1],
|
|
[Define if the <pthread.h> defines PTHREAD_MUTEX_RECURSIVE.])])
|
|
fi
|
|
gl_PREREQ_LOCK
|
|
])
|
|
|
|
# Prerequisites of lib/glthread/lock.c.
|
|
AC_DEFUN([gl_PREREQ_LOCK], [:])
|