mirror of
https://git.savannah.gnu.org/git/gnulib.git
synced 2025-08-16 01:22:18 +03:00
a3fd683de3
* build-aux/gendocs.sh (version): * doc/gendocs_template: * doc/gendocs_template_min: * doc/gnulib.texi: * lib/version-etc.c (COPYRIGHT_YEAR): Update copyright dates by hand in templates and the like. * all files: Run 'make update-copyright'.
30 lines
1.0 KiB
Plaintext
30 lines
1.0 KiB
Plaintext
# ld-output-def.m4 serial 2
|
|
dnl Copyright (C) 2008-2017 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Simon Josefsson
|
|
|
|
# gl_LD_OUTPUT_DEF()
|
|
# -------------
|
|
# Check if linker supports -Wl,--output-def and define automake
|
|
# conditional HAVE_LD_OUTPUT_DEF if it is.
|
|
AC_DEFUN([gl_LD_OUTPUT_DEF],
|
|
[
|
|
AC_CACHE_CHECK([if gcc/ld supports -Wl,--output-def],
|
|
[gl_cv_ld_output_def],
|
|
[if test "$enable_shared" = no; then
|
|
gl_cv_ld_output_def="not needed, shared libraries are disabled"
|
|
else
|
|
gl_ldflags_save=$LDFLAGS
|
|
LDFLAGS="-Wl,--output-def,conftest.def"
|
|
AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
|
|
[gl_cv_ld_output_def=yes],
|
|
[gl_cv_ld_output_def=no])
|
|
rm -f conftest.def
|
|
LDFLAGS="$gl_ldflags_save"
|
|
fi])
|
|
AM_CONDITIONAL([HAVE_LD_OUTPUT_DEF], test "x$gl_cv_ld_output_def" = "xyes")
|
|
])
|