mirror of
https://git.savannah.gnu.org/git/gnulib.git
synced 2025-08-16 01:22:18 +03:00
03c3f38b55
This is useful for Emacs. * modules/msvc-nothrow (configure.ac): Invoke gl_MODULE_INDICATOR. * lib/accept4.c: Include <io.h> as an alternative to msvc-nothrow.h. * lib/error.c: Likewise. * lib/fcntl.c: Likewise. * lib/flock.c: Likewise. * lib/fstat.c: Likewise. * lib/fsync.c: Likewise. * lib/ioctl.c: Likewise. * lib/isapipe.c: Likewise. * lib/lseek.c: Likewise. * lib/nonblocking.c: Likewise. * lib/poll.c: Likewise. * lib/select.c: Likewise. * lib/sockets.h: Likewise. * lib/sockets.c: Likewise. * lib/stdio-read.c: Likewise. * lib/stdio-write.c: Likewise. * lib/utimens.c: Likewise. * lib/w32sock.h: Likewise. * lib/w32spawn.h: Likewise. * tests/test-cloexec.c: Likewise. * tests/test-dup-safer.c: Likewise. * tests/test-dup2.c: Likewise. * tests/test-dup3.c: Likewise. * tests/test-fcntl.c: Likewise. * tests/test-pipe.c: Likewise. * tests/test-pipe2.c: Likewise. * lib/ftruncate.c: Likewise. (chsize_nothrow): Renamed from chsize. * lib/msvc-nothrow.c: Don't include msvc-inval.h if HAVE_MSVC_INVALID_PARAMETER_HANDLER is not defined. * lib/close.c: Likewise. * lib/dup.c: Likewise. * lib/fclose.c: Likewise. * lib/raise.c: Likewise. * tests/test-fgetc.c: Likewise. * tests/test-fputc.c: Likewise. * tests/test-fread.c: Likewise. * tests/test-fwrite.c: Likewise. * lib/getdtablesize.c: Likewise. (_setmaxstdio_nothrow): Renamed from _setmaxstdio. * lib/isatty.c: Don't include msvc-inval.h if HAVE_MSVC_INVALID_PARAMETER_HANDLER is not defined. Include <io.h> as an alternative to msvc-nothrow.h. * lib/read.c: Likewise. * lib/write.c: Likewise. * lib/dup2.c: Likewise. (dup2_nothrow): New function. (ms_windows_dup2): Use it. * m4/close.m4 (gl_FUNC_CLOSE): Invoke gl_MSVC_INVAL and test HAVE_MSVC_INVALID_PARAMETER_HANDLER only if gl_MSVC_INVAL is defined. * m4/dup.m4 (gl_FUNC_DUP): Likewise. * m4/fdopen.m4 (gl_FUNC_FDOPEN): Likewise. * m4/raise.m4 (gl_FUNC_RAISE): Likewise. * m4/read.m4 (gl_FUNC_READ): Likewise. * m4/write.m4 (gl_FUNC_WRITE): Likewise. * doc/windows-without-msvc.texi: New file. * doc/gnulib.texi (Native Windows Support without MSVC Support): New section.
51 lines
1.4 KiB
Plaintext
51 lines
1.4 KiB
Plaintext
# fdopen.m4 serial 4
|
|
dnl Copyright (C) 2011-2017 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_FUNC_FDOPEN],
|
|
[
|
|
AC_REQUIRE([gl_STDIO_H_DEFAULTS])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
m4_ifdef([gl_MSVC_INVAL], [
|
|
AC_REQUIRE([gl_MSVC_INVAL])
|
|
if test $HAVE_MSVC_INVALID_PARAMETER_HANDLER = 1; then
|
|
REPLACE_FDOPEN=1
|
|
fi
|
|
])
|
|
if test $REPLACE_FDOPEN = 0; then
|
|
dnl Test whether fdopen() sets errno when it fails due to a bad fd argument.
|
|
AC_CACHE_CHECK([whether fdopen sets errno], [gl_cv_func_fdopen_works],
|
|
[
|
|
AC_RUN_IFELSE(
|
|
[AC_LANG_SOURCE([[
|
|
#include <stdio.h>
|
|
#include <errno.h>
|
|
int
|
|
main (void)
|
|
{
|
|
FILE *fp;
|
|
errno = 0;
|
|
fp = fdopen (-1, "r");
|
|
if (fp == NULL && errno == 0)
|
|
return 1;
|
|
return 0;
|
|
}]])],
|
|
[gl_cv_func_fdopen_works=yes],
|
|
[gl_cv_func_fdopen_works=no],
|
|
[case "$host_os" in
|
|
mingw*) gl_cv_func_fdopen_works="guessing no" ;;
|
|
*) gl_cv_func_fdopen_works="guessing yes" ;;
|
|
esac
|
|
])
|
|
])
|
|
case "$gl_cv_func_fdopen_works" in
|
|
*no) REPLACE_FDOPEN=1 ;;
|
|
esac
|
|
fi
|
|
])
|
|
|
|
dnl Prerequisites of lib/fdopen.c.
|
|
AC_DEFUN([gl_PREREQ_FDOPEN], [])
|