mirror of
https://sourceware.org/git/glibc.git
synced 2025-10-28 23:34:53 +03:00
ed1ac6a2d6
1998-08-24 16:34 Ulrich Drepper <drepper@cygnus.com> * debug/catchsegv.sh: Handle text preceding backtrace better. * sysdeps/generic/segfault.c: Allow register dump. Allow handler to be installed for other signals than SIGSEGV. * sysdeps/generic/register-dump.h: New file. * sysdeps/i386/register-dump.h: New file. * sysdeps/powerpc/register-dump.h: New file. * sysdeps/unix/sysv/linux/i386/profil-counter.h: Use macros from sigcontextinfo.h. * sysdeps/unix/sysv/linux/powerpc/profil-counter.h: Use i386 version. 1998-08-24 Geoff Keating <geoffk@ozemail.com.au> * sysdeps/unix/sysv/linux/powerpc/sigcontextinfo.h: New file. 1998-08-09 Geoff Keating <geoffk@ozemail.com.au> * sysdeps/unix/sysv/linux/powerpc/chown.c: New file. * sysdeps/unix/sysv/linux/powerpc/lchown.S: New file. * sysdeps/unix/sysv/linux/powerpc/syscalls.list: Add chown, remove getresuid, getresgid. 1998-08-16 Geoff Keating <geoffk@ozemail.com.au> * sysdeps/unix/sysv/linux/powerpc/clone.S: Fix bugs. Set up stack pointer in userland. 1998-08-21 Andreas Schwab <schwab@issan.informatik.uni-dortmund.de> * sysdeps/unix/sysv/linux/sys/mount.h (MNT_FORCE): Define as enum and fix value. 1998-08-22 Andreas Schwab <schwab@issan.informatik.uni-dortmund.de> * elf/ldd.bash.in: Add missing quotes around $file. Make loop over arguments Bourne shell compatible. Don't exit unsuccessfully if nonelf returns successfully. Avoid duplicating most of the script. * sysdeps/unix/sysv/linux/ldd-rewrite.sed: Add missing quotes around $file. 1998-08-24 10:37 Andreas Schwab <schwab@issan.informatik.uni-dortmund.de> * libio/Versions (_IO_do_write, _IO_file_attach, _IO_file_close_it, _IO_file_finish, _IO_file_fopen, _IO_file_init, _IO_file_overflow, _IO_file_seekoff, _IO_file_setbuf, _IO_file_sync, _IO_file_underflow, _IO_file_write, _IO_file_xsputn): Added to GLIBC_2.1. * libio/fileops.c (_IO_do_write, _IO_file_attach, _IO_file_close_it, _IO_file_finish, _IO_file_fopen, _IO_file_init, _IO_file_overflow, _IO_file_seekoff, _IO_file_setbuf, _IO_file_sync, _IO_file_underflow, _IO_file_write, _IO_file_xsputn): Change the prefix to "_IO_new_". Added to GLIBC_2.1. * libio/libioP.h (_IO_do_write, _IO_file_attach, _IO_file_close_it, _IO_file_finish, _IO_file_fopen, _IO_file_init, _IO_file_overflow, _IO_file_seekoff, _IO_file_setbuf, _IO_file_sync, _IO_file_underflow, _IO_file_write, _IO_file_xsputn): Add prototypes for the prefix "_IO_new_". * libio/oldfileops.c (_IO_do_write, _IO_file_attach, _IO_file_close_it, _IO_file_finish, _IO_file_fopen, _IO_file_init, _IO_file_overflow, _IO_file_seekoff, _IO_file_setbuf, _IO_file_sync, _IO_file_underflow, _IO_file_write, _IO_file_xsputn): Added to GLIBC_2.0. * csu/initfini.c: Return to .text before __gmon_start__. * elf/elf.h (EM_FAKE_ALPHA): Rename from EM_OLD_ALPHA. (STO_MIPS_*): Rename from STO_*. (STB_MIPS_SPLIT_COMMON): Rename from STB_SPLIT_COMMON. (STO_ALPHA_NOPV, STO_ALPHA_STD_GPLOAD): New. * math/atest-exp.c (mpn_bitsize): Fix bit location calculation. (main): e3s is negative on zero. * math/atest-exp2.c: Likewise. 1998-08-23 Andreas Jaeger <aj@arthur.rhein-neckar.de> * Makerules (install): Add comment about absolute paths.
88 lines
2.7 KiB
ArmAsm
88 lines
2.7 KiB
ArmAsm
/* Wrapper around clone system call.
|
|
Copyright (C) 1997, 1998 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
|
|
/* This is the only really unusual system call in PPC linux, but not
|
|
because of any weirdness in the system call itself; because of
|
|
all the freaky stuff we have to do to make the call useful. */
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg); */
|
|
|
|
ENTRY(__clone)
|
|
/* Check for child_stack == NULL || fn == NULL. */
|
|
cmpwi %cr0,%r4,0
|
|
cmpwi %cr1,%r3,0
|
|
cror cr0*4+eq,cr1*4+eq,cr0*4+eq
|
|
beq- %cr0,L(badargs)
|
|
|
|
/* Set up stack frame for parent. */
|
|
stwu %r1,-32(%r1)
|
|
stmw %r29,16(%r1)
|
|
|
|
/* Set up stack frame for child. */
|
|
clrrwi %r4,%r4,4
|
|
li %r0,0
|
|
stwu %r0,-16(%r4)
|
|
|
|
/* Save fn, args, stack across syscall. */
|
|
mr %r29,%r3 /* Function in r29. */
|
|
mr %r30,%r4 /* Stack pointer in r30. */
|
|
mr %r31,%r6 /* Argument in r31. */
|
|
|
|
/* 'flags' argument is first parameter to clone syscall. (The other
|
|
argument is the stack pointer, already in r4.) */
|
|
mr %r3,%r5
|
|
|
|
/* Do the call. */
|
|
DO_CALL(SYS_ify(clone))
|
|
|
|
/* Check for child process. */
|
|
cmpwi %cr1,%r3,0
|
|
crandc cr1*4+eq,cr1*4+eq,cr0*4+so
|
|
bne- %cr1,L(parent) /* The '-' is to minimise the race. */
|
|
|
|
/* On at least mklinux DR3a5, clone() doesn't actually change
|
|
the stack pointer. I'm pretty sure this is a bug, because
|
|
it adds a race condition if a signal is sent to a thread
|
|
just after it is created (in the previous three instructions). */
|
|
mr %r1,%r30
|
|
/* Call procedure. */
|
|
mtctr %r29
|
|
mr %r3,%r31
|
|
bctrl
|
|
/* Call _exit with result from procedure. */
|
|
b JUMPTARGET(_exit)
|
|
|
|
L(parent):
|
|
/* Parent. Restore registers & return. */
|
|
lmw %r29,16(%r1)
|
|
addi %r1,%r1,32
|
|
bnslr+
|
|
b JUMPTARGET(__syscall_error)
|
|
|
|
L(badargs):
|
|
li %r3,EINVAL
|
|
b JUMPTARGET(__syscall_error)
|
|
END (__clone)
|
|
|
|
weak_alias (__clone, clone)
|