mirror of
https://sourceware.org/git/glibc.git
synced 2025-09-08 13:52:10 +03:00
15eab1e3e8
On i386, since EAX, ECX and EDX are caller-saved, there are no need to save and restore EAX, ECX and EDX in getcontext, setcontext and swapcontext. They just need to clear EAX on success. The extra scratch registers are needed to enable CET. Tested on i386. Reviewed-by: Adhemerval Zanella <adhemerval.zanella@linaro.org>
103 lines
2.9 KiB
ArmAsm
103 lines
2.9 KiB
ArmAsm
/* Save current context and install the given one.
|
|
Copyright (C) 2001-2020 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Ulrich Drepper <drepper@redhat.com>, 2001.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
#include "ucontext_i.h"
|
|
|
|
|
|
ENTRY(__swapcontext)
|
|
/* Load address of the context data structure we save in. */
|
|
movl 4(%esp), %eax
|
|
|
|
/* Save the preserved register values and the return address. */
|
|
movl %edi, oEDI(%eax)
|
|
movl %esi, oESI(%eax)
|
|
movl %ebp, oEBP(%eax)
|
|
movl (%esp), %ecx
|
|
movl %ecx, oEIP(%eax)
|
|
leal 4(%esp), %ecx
|
|
movl %ecx, oESP(%eax)
|
|
movl %ebx, oEBX(%eax)
|
|
|
|
/* Save the FS segment register. */
|
|
xorl %edx, %edx
|
|
movw %fs, %dx
|
|
movl %edx, oFS(%eax)
|
|
|
|
/* We have separate floating-point register content memory on the
|
|
stack. We use the __fpregs_mem block in the context. Set the
|
|
links up correctly. */
|
|
leal oFPREGSMEM(%eax), %ecx
|
|
movl %ecx, oFPREGS(%eax)
|
|
/* Save the floating-point context. */
|
|
fnstenv (%ecx)
|
|
|
|
/* Load address of the context data structure we have to load. */
|
|
movl 8(%esp), %ecx
|
|
|
|
/* Save the current signal mask and install the new one. */
|
|
pushl %ebx
|
|
leal oSIGMASK(%eax), %edx
|
|
leal oSIGMASK(%ecx), %ecx
|
|
movl $SIG_SETMASK, %ebx
|
|
movl $__NR_sigprocmask, %eax
|
|
ENTER_KERNEL
|
|
popl %ebx
|
|
cmpl $-4095, %eax /* Check %eax for error. */
|
|
jae SYSCALL_ERROR_LABEL /* Jump to error handler if error. */
|
|
|
|
/* EAX was modified, reload it. */
|
|
movl 8(%esp), %eax
|
|
|
|
/* Restore the floating-point context. Not the registers, only the
|
|
rest. */
|
|
movl oFPREGS(%eax), %ecx
|
|
fldenv (%ecx)
|
|
|
|
/* Restore the FS segment register. We don't touch the GS register
|
|
since it is used for threads. */
|
|
movl oFS(%eax), %edx
|
|
movw %dx, %fs
|
|
|
|
/* Fetch the address to return to. */
|
|
movl oEIP(%eax), %ecx
|
|
|
|
/* Load the new stack pointer. */
|
|
movl oESP(%eax), %esp
|
|
|
|
/* Push the return address on the new stack so we can return there. */
|
|
pushl %ecx
|
|
|
|
/* Load the values of all the preserved registers (except ESP). */
|
|
movl oEDI(%eax), %edi
|
|
movl oESI(%eax), %esi
|
|
movl oEBP(%eax), %ebp
|
|
movl oEBX(%eax), %ebx
|
|
|
|
/* All done, return 0 for success. */
|
|
xorl %eax, %eax
|
|
|
|
/* The following 'ret' will pop the address of the code and jump
|
|
to it. */
|
|
ret
|
|
PSEUDO_END(__swapcontext)
|
|
|
|
weak_alias (__swapcontext, swapcontext)
|