mirror of
https://sourceware.org/git/glibc.git
synced 2025-11-03 20:53:13 +03:00
af85385f31
<locale.h> is specified to define locale_t in POSIX.1-2008, and so are all of the headers that define functions that take locale_t arguments. Under _GNU_SOURCE, the additional headers that define such functions have also always defined locale_t. Therefore, there is no need to use __locale_t in public function prototypes, nor in any internal code. * ctype/ctype-c99_l.c, ctype/ctype.h, ctype/ctype_l.c * include/monetary.h, include/stdlib.h, include/time.h * include/wchar.h, locale/duplocale.c, locale/freelocale.c * locale/global-locale.c, locale/langinfo.h, locale/locale.h * locale/localeinfo.h, locale/newlocale.c * locale/nl_langinfo_l.c, locale/uselocale.c * localedata/bug-usesetlocale.c, localedata/tst-xlocale2.c * stdio-common/vfscanf.c, stdlib/monetary.h, stdlib/stdlib.h * stdlib/strfmon_l.c, stdlib/strtod_l.c, stdlib/strtof_l.c * stdlib/strtol.c, stdlib/strtol_l.c, stdlib/strtold_l.c * stdlib/strtoll_l.c, stdlib/strtoul_l.c, stdlib/strtoull_l.c * string/strcasecmp.c, string/strcoll_l.c, string/string.h * string/strings.h, string/strncase.c, string/strxfrm_l.c * sysdeps/ieee754/float128/strtof128_l.c * sysdeps/ieee754/float128/wcstof128.c * sysdeps/ieee754/float128/wcstof128_l.c * sysdeps/ieee754/ldbl-128ibm/strtold_l.c * sysdeps/ieee754/ldbl-64-128/strtold_l.c * sysdeps/ieee754/ldbl-opt/nldbl-compat.c * sysdeps/ieee754/ldbl-opt/nldbl-strfmon_l.c * sysdeps/ieee754/ldbl-opt/nldbl-strtold_l.c * sysdeps/ieee754/ldbl-opt/nldbl-wcstold_l.c * sysdeps/powerpc/powerpc32/power7/strcasecmp.S * sysdeps/powerpc/powerpc64/power7/strcasecmp.S * sysdeps/x86_64/strcasecmp_l-nonascii.c * sysdeps/x86_64/strncase_l-nonascii.c, time/strftime_l.c * time/strptime_l.c, time/time.h, wcsmbs/mbsrtowcs_l.c * wcsmbs/wchar.h, wcsmbs/wcscasecmp.c, wcsmbs/wcsncase.c * wcsmbs/wcstod.c, wcsmbs/wcstod_l.c, wcsmbs/wcstof.c * wcsmbs/wcstof_l.c, wcsmbs/wcstol_l.c, wcsmbs/wcstold.c * wcsmbs/wcstold_l.c, wcsmbs/wcstoll_l.c, wcsmbs/wcstoul_l.c * wcsmbs/wcstoull_l.c, wctype/iswctype_l.c * wctype/towctrans_l.c, wctype/wcfuncs_l.c * wctype/wctrans_l.c, wctype/wctype.h, wctype/wctype_l.c: Change all uses of __locale_t to locale_t.
130 lines
3.7 KiB
ArmAsm
130 lines
3.7 KiB
ArmAsm
/* Optimized strcasecmp implementation for PowerPC32.
|
|
Copyright (C) 2011-2017 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include <locale-defines.h>
|
|
|
|
/* int [r3] strcasecmp (const char *s1 [r3], const char *s2 [r4] )
|
|
|
|
or if defined USE_IN_EXTENDED_LOCALE_MODEL:
|
|
|
|
int [r3] strcasecmp_l (const char *s1 [r3], const char *s2 [r4],
|
|
locale_t loc [r5]) */
|
|
|
|
#ifndef STRCMP
|
|
# define __STRCMP __strcasecmp
|
|
# define STRCMP strcasecmp
|
|
#endif
|
|
|
|
ENTRY (__STRCMP)
|
|
|
|
#define rRTN r3 /* Return value */
|
|
#define rSTR1 r5 /* 1st string */
|
|
#define rSTR2 r4 /* 2nd string */
|
|
#define rLOCARG r5 /* 3rd argument: locale_t */
|
|
#define rCHAR1 r6 /* Byte read from 1st string */
|
|
#define rCHAR2 r7 /* Byte read from 2nd string */
|
|
#define rADDR1 r8 /* Address of tolower(rCHAR1) */
|
|
#define rADDR2 r12 /* Address of tolower(rCHAR2) */
|
|
#define rLWR1 r8 /* Byte tolower(rCHAR1) */
|
|
#define rLWR2 r12 /* Byte tolower(rCHAR2) */
|
|
#define rTMP r0
|
|
#define rGOT r9 /* Address of the Global Offset Table */
|
|
#define rLOC r11 /* Default locale address */
|
|
|
|
cmpw cr7, r3, r4
|
|
#ifndef USE_IN_EXTENDED_LOCALE_MODEL
|
|
# ifdef SHARED
|
|
mflr rTMP
|
|
bcl 20,31,.L1
|
|
.L1: mflr rGOT
|
|
addis rGOT, rGOT, _GLOBAL_OFFSET_TABLE_-.L1@ha
|
|
addi rGOT, rGOT, _GLOBAL_OFFSET_TABLE_-.L1@l
|
|
lwz rLOC, __libc_tsd_LOCALE@got@tprel(rGOT)
|
|
add rLOC, rLOC, __libc_tsd_LOCALE@tls
|
|
lwz rLOC, 0(rLOC)
|
|
mtlr rTMP
|
|
# else
|
|
lis rTMP,_GLOBAL_OFFSET_TABLE_@ha
|
|
la rLOC,_GLOBAL_OFFSET_TABLE_@l(rTMP)
|
|
lwz rLOC, __libc_tsd_LOCALE@got@tprel(rGOT)
|
|
add rLOC, rLOC, __libc_tsd_LOCALE@tls
|
|
lwz rLOC, 0(rLOC)
|
|
# endif /* SHARED */
|
|
#else
|
|
mr rLOC, rLOCARG
|
|
#endif
|
|
mr rSTR1, rRTN
|
|
lwz rLOC, LOCALE_CTYPE_TOLOWER(rLOC)
|
|
li rRTN, 0
|
|
beqlr cr7
|
|
|
|
/* Unrolling loop for POWER: loads are done with 'lbz' plus
|
|
offset and string descriptors are only updated in the end
|
|
of loop unrolling. */
|
|
|
|
L(loop):
|
|
lbz rCHAR1, 0(rSTR1) /* Load char from s1 */
|
|
lbz rCHAR2, 0(rSTR2) /* Load char from s2 */
|
|
sldi rADDR1, rCHAR1, 2 /* Calculate address for tolower(*s1) */
|
|
sldi rADDR2, rCHAR2, 2 /* Calculate address for tolower(*s2) */
|
|
lwzx rLWR1, rLOC, rADDR1 /* Load tolower(*s1) */
|
|
lwzx rLWR2, rLOC, rADDR2 /* Load tolower(*s2) */
|
|
cmpwi cr7, rCHAR1, 0 /* *s1 == '\0' ? */
|
|
subf. r3, rLWR2, rLWR1
|
|
bnelr
|
|
beqlr cr7
|
|
lbz rCHAR1, 1(rSTR1)
|
|
lbz rCHAR2, 1(rSTR2)
|
|
sldi rADDR1, rCHAR1, 2
|
|
sldi rADDR2, rCHAR2, 2
|
|
lwzx rLWR1, rLOC, rADDR1
|
|
lwzx rLWR2, rLOC, rADDR2
|
|
cmpwi cr7, rCHAR1, 0
|
|
subf. r3, rLWR2, rLWR1
|
|
bnelr
|
|
beqlr cr7
|
|
lbz rCHAR1, 2(rSTR1)
|
|
lbz rCHAR2, 2(rSTR2)
|
|
sldi rADDR1, rCHAR1, 2
|
|
sldi rADDR2, rCHAR2, 2
|
|
lwzx rLWR1, rLOC, rADDR1
|
|
lwzx rLWR2, rLOC, rADDR2
|
|
cmpwi cr7, rCHAR1, 0
|
|
subf. r3, rLWR2, rLWR1
|
|
bnelr
|
|
beqlr cr7
|
|
lbz rCHAR1, 3(rSTR1)
|
|
lbz rCHAR2, 3(rSTR2)
|
|
/* Increment both string descriptors */
|
|
addi rSTR1, rSTR1, 4
|
|
addi rSTR2, rSTR2, 4
|
|
sldi rADDR1, rCHAR1, 2
|
|
sldi rADDR2, rCHAR2, 2
|
|
lwzx rLWR1, rLOC, rADDR1
|
|
lwzx rLWR2, rLOC, rADDR2
|
|
cmpwi cr7, rCHAR1, 0
|
|
subf. r3, rLWR2, rLWR1
|
|
bnelr
|
|
bne cr7,L(loop)
|
|
blr
|
|
END (__STRCMP)
|
|
|
|
weak_alias (__STRCMP, STRCMP)
|
|
libc_hidden_builtin_def (__STRCMP)
|