mirror of
https://sourceware.org/git/glibc.git
synced 2025-07-07 12:21:14 +03:00
edac0e8f44
* elf/tls-macros.h: Add Sparc64 defines. * sysdeps/sparc/sparc64/dl-machine.h (sparc64_fixup_plt): Mark as always_inline. (elf_machine_fixup_plt): Likewise. (elf_machine_rela): Handle TLS relocations. (elf_machine_type_cleaa): Likewise. * sysdeps/unix/sysv/linux/sparc/sparc64/sysdep.h (SYSCALL_ERROR_HANDLER_ENTRY): Use sethi/or for GOT reloc. It does not always fit in R_SPARC_GOT13 when building -fPIC. Also, add TLS handling. * sysdeps/unix/sysv/linux/configure.in (arch_minimum_kernel): Increase it to 2.4.21 for sparc64. * sysdeps/unix/sysv/linux/sparc/sparc32/clone.S: NULL terminate backtrace by zero'ing out %fp. Store away flags, func_ptr, and func_arg in global registers not local registers. * sysdeps/unix/sysv/linux/sparc/sparc64/clone.S: Handle PTID, TLS, and CTID arguments properly. Add RESET_PID handling. * sysdeps/unix/sysv/linux/sparc/sparc64/pause.c: Rework so that we do not invoke __sigprocmask(). We can always assume rt signals are present on sparc64, so just do an inline syscall. 2005-04-13 Jakub Jelinek <jakub@redhat.com> * sysdeps/sparc/sparc64/dl-machine.h: Add dl_machine_h multiple inclusion guard for the first half of the header. (elf_machine_type_class, ELF_MACHINE_JMP_SLOT, ELF_MACHINE_NO_REL, ELF_MACHINE_PLTREL_OVERLAP, elf_machine_runtime_setup, elf_machine_relplt, DL_STACK_END, RTLD_START): Move into the #ifndef dl_machine_h guarded part of the header.
108 lines
2.4 KiB
ArmAsm
108 lines
2.4 KiB
ArmAsm
/* Copyright (C) 1996, 1997, 1998, 2000, 2003, 2004
|
|
Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Richard Henderson (rth@tamu.edu).
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <asm/errno.h>
|
|
#include <asm/unistd.h>
|
|
#include <tcb-offsets.h>
|
|
|
|
#define CLONE_VM 0x00000100
|
|
#define CLONE_THREAD 0x00010000
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
|
|
pid_t *ptid, void *tls, pid_t *ctid); */
|
|
|
|
.text
|
|
.align 4
|
|
.globl __clone
|
|
.type __clone,@function
|
|
|
|
__clone:
|
|
save %sp,-96,%sp
|
|
|
|
/* sanity check arguments */
|
|
orcc %i0,%g0,%g2
|
|
be .Lerror
|
|
orcc %i1,%g0,%o1
|
|
be .Lerror
|
|
mov %i2,%o0
|
|
|
|
/* The child_stack is the top of the stack, allocate one
|
|
whole stack frame from that as this is what the kernel
|
|
expects. */
|
|
sub %o1, 96, %o1
|
|
mov %i3, %g3
|
|
mov %i2, %g4
|
|
|
|
/* ptid */
|
|
mov %i4,%o2
|
|
/* tls */
|
|
mov %i5,%o3
|
|
/* ctid */
|
|
ld [%fp+92],%o4
|
|
|
|
/* Do the system call */
|
|
set __NR_clone,%g1
|
|
ta 0x10
|
|
bcs .Lerror
|
|
tst %o1
|
|
bne __thread_start
|
|
nop
|
|
ret
|
|
restore %o0,%g0,%o0
|
|
|
|
.Lerror:
|
|
call __errno_location
|
|
or %g0,EINVAL,%i0
|
|
st %i0,[%o0]
|
|
ret
|
|
restore %g0,-1,%o0
|
|
|
|
.size __clone, .-__clone
|
|
|
|
.type __thread_start,@function
|
|
|
|
__thread_start:
|
|
#ifdef RESET_PID
|
|
sethi %hi(CLONE_THREAD), %l0
|
|
andcc %g4, %l0, %g0
|
|
bne 1f
|
|
andcc %g4, CLONE_VM, %g0
|
|
bne,a 2f
|
|
mov -1,%o0
|
|
set __NR_getpid,%g1
|
|
ta 0x10
|
|
2:
|
|
st %o0,[%g7 + PID]
|
|
st %o0,[%g7 + TID]
|
|
1:
|
|
#endif
|
|
mov %g0, %fp /* terminate backtrace */
|
|
call %g2
|
|
mov %g3,%o0
|
|
call _exit,0
|
|
nop
|
|
|
|
.size __thread_start, .-__thread_start
|
|
|
|
weak_alias(__clone, clone)
|