mirror of
https://sourceware.org/git/glibc.git
synced 2025-11-03 20:53:13 +03:00
3081378bb2
1998-05-19 15:58 Ulrich Drepper <drepper@cygnus.com> * elf/rtld.c (process_envvars): Fix typo. Don't handle LD_PROFILE_OUTPUT in SUID binaries. * intl/dcgettext.c: In SUID binaries don't let language part of locale value contain path elements. * intl/explodename.h: Define new function _nl_find_language. * intl/loadinfo.h: Declare _nl_find_language. * locale/findlocale.c (_nl_find_locale): Use _nl_find_locale to get language part it drop the value is path element is contained. * locale/setlocale.c: Fix typo. 1998-05-18 Philip Blundell <Philip.Blundell@pobox.com> * sysdeps/unix/sysv/linux/arm/socket.S: Correct handling of arguments. * sysdeps/arm/strlen.S: Support both big and little endian processors. * sysdeps/arm/sysdep.h (ALIGNARG): ELF .align directive uses a log, not a byte-count. * sysdeps/unix/arm/sysdep.S (syscall_error): Use C_SYMBOL_NAME for a.out compatibility. 1998-05-19 Andreas Jaeger <aj@arthur.rhein-neckar.de> * sysdeps/unix/bsd/vax/vfork.S: Fix the "the the" problems. * sysdeps/unix/bsd/sun/m68k/vfork.S: Likewise. * sysdeps/unix/bsd/hp/m68k/vfork.S: Likewise. * posix/unistd.h: Likewise. * math/math.h: Likewise. * manual/users.texi (Manipulating the Database): Likewise. * manual/signal.texi (Job Control Signals): Likewise. * manual/message.texi (The gencat program): Likewise. * manual/filesys.texi (Hard Links): Likewise. * manual/math.texi (SVID Random): Likewise. * manual/llio.texi (Waiting for I/O): Likewise. * manual/io.texi (File Name Errors): Likewise. * manual/conf.texi (String Parameters): Likewise. * manual/arith.texi (Infinity): Likewise. * malloc/malloc.c: Likewise. * hurd/hurdsig.c (_hurd_internal_post_signal): Likewise. * csu/Makefile: Likewise.
64 lines
2.7 KiB
ArmAsm
64 lines
2.7 KiB
ArmAsm
/* Copyright (C) 1998 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Code contributed by Matthew Wilcox <willy@odie.barnet.ac.uk>
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
/* size_t strlen(const char *S)
|
|
* entry: r0 -> string
|
|
* exit: r0 = len
|
|
*/
|
|
|
|
ENTRY(strlen)
|
|
bic r1, r0, $3 @ addr of word containing first byte
|
|
ldr r2, [r1], $4 @ get the first word
|
|
ands r3, r0, $3 @ how many bytes are duff?
|
|
rsb r0, r3, $0 @ get - that number into counter.
|
|
beq Laligned @ skip into main check routine if no
|
|
@ more
|
|
#ifdef __ARMEB__
|
|
orr r2, r2, $0xff000000 @ set this byte to non-zero
|
|
subs r3, r3, $1 @ any more to do?
|
|
orrgt r2, r2, $0x00ff0000 @ if so, set this byte
|
|
subs r3, r3, $1 @ more?
|
|
orrgt r2, r2, $0x0000ff00 @ then set.
|
|
#else
|
|
orr r2, r2, $0x000000ff @ set this byte to non-zero
|
|
subs r3, r3, $1 @ any more to do?
|
|
orrgt r2, r2, $0x0000ff00 @ if so, set this byte
|
|
subs r3, r3, $1 @ more?
|
|
orrgt r2, r2, $0x00ff0000 @ then set.
|
|
#endif
|
|
Laligned: @ here, we have a word in r2. Does it
|
|
tst r2, $0x000000ff @ contain any zeroes?
|
|
tstne r2, $0x0000ff00 @
|
|
tstne r2, $0x00ff0000 @
|
|
tstne r2, $0xff000000 @
|
|
addne r0, r0, $4 @ if not, the string is 4 bytes longer
|
|
ldrne r2, [r1], $4 @ and we continue to the next word
|
|
bne Laligned @
|
|
Llastword: @ drop through to here once we find a
|
|
tst r2, $0x000000ff @ word that has a zero byte in it
|
|
addne r0, r0, $1 @
|
|
tstne r2, $0x0000ff00 @ and add up to 3 bytes on to it
|
|
addne r0, r0, $1 @
|
|
tstne r2, $0x00ff0000 @ (if first three all non-zero, 4th
|
|
addne r0, r0, $1 @ must be zero)
|
|
RETINSTR(mov,pc,lr)
|
|
END(strlen)
|