mirror of
https://sourceware.org/git/glibc.git
synced 2025-11-03 20:53:13 +03:00
2a051a7d1a
2003-02-07 Kaz Kojima <kkojima@rr.iij4u.or.jp> * elf/tls-macros.h: Add non-PIC TLS macros and fix clobber list for SH. * sysdeps/unix/sysv/linux/sh/brk.c: Add SYSCALL_INST_PAD after the trapa instruction. * sysdeps/unix/sysv/linux/sh/clone.S (__clone): Add additional parameters. * sysdeps/unix/sysv/linux/sh/sh4/sysdep.h: New file. (NEED_SYSCALL_INST_PAD): Define. * sysdeps/unix/sysv/linux/sh/sys/user.h (start_thread): Undef to avoid to use definition for the kernel. * sysdeps/unix/sysv/linux/sh/sysdep.h (SYSCALL_ERROR_HANDLER): Save and restore the frame pointer. (SYSCALL_INST_PAD): Define. (INLINE_SYSCALL): Make use of INTERNAL_SYSCALL. (INTERNAL_SYSCALL): Make use of ERR parameter. Add SYSCALL_INST_PAD after trapa instruction. (INTERNAL_SYSCALL_DECL, INTERNAL_SYSCALL_ERRNO, INTERNAL_SYSCALL_ERROR_P): Adjust accordingly.
100 lines
2.3 KiB
ArmAsm
100 lines
2.3 KiB
ArmAsm
/* Copyright (C) 1999, 2000, 2003 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
|
|
pid_t *ptid, void *tls, pid_t *ctid); */
|
|
|
|
.text
|
|
ENTRY(__clone)
|
|
/* sanity check arguments. */
|
|
tst r4, r4
|
|
bf/s 1f
|
|
tst r5, r5
|
|
bf/s 1f
|
|
mov #-EINVAL,r0
|
|
bra .Lsyscall_error
|
|
nop
|
|
1:
|
|
/* insert the args onto the new stack */
|
|
mov.l r7, @-r5
|
|
/* save the function pointer as the 0th element */
|
|
mov.l r4, @-r5
|
|
|
|
/* do the system call */
|
|
mov r6, r4
|
|
mov.l @r15, r6
|
|
mov.l @(8,r15), r7
|
|
mov.l @(4,r15), r0
|
|
mov #+SYS_ify(clone), r3
|
|
trapa #0x15
|
|
mov r0, r1
|
|
mov #-12, r2
|
|
shad r2, r1
|
|
not r1, r1 // r1=0 means r0 = -1 to -4095
|
|
tst r1, r1 // i.e. error in linux
|
|
bf .Lclone_end
|
|
.Lsyscall_error:
|
|
SYSCALL_ERROR_HANDLER
|
|
.Lclone_end:
|
|
tst r0, r0
|
|
bt 2f
|
|
.Lpseudo_end:
|
|
rts
|
|
nop
|
|
2:
|
|
/* thread starts */
|
|
mov.l @r15, r1
|
|
jsr @r1
|
|
mov.l @(4,r15), r4
|
|
|
|
/* we are done, passing the return value through r0 */
|
|
mov.l .L3, r1
|
|
#ifdef SHARED
|
|
mov.l r12, @-r15
|
|
sts.l pr, @-r15
|
|
mov r0, r4
|
|
mova .LG, r0
|
|
mov.l .LG, r12
|
|
add r0, r12
|
|
mova .L3, r0
|
|
add r0, r1
|
|
jsr @r1
|
|
nop
|
|
lds.l @r15+, pr
|
|
rts
|
|
mov.l @r15+, r12
|
|
#else
|
|
jmp @r1
|
|
mov r0, r4
|
|
#endif
|
|
.align 2
|
|
.LG:
|
|
.long _GLOBAL_OFFSET_TABLE_
|
|
.L3:
|
|
.long PLTJMP(C_SYMBOL_NAME(_exit))
|
|
PSEUDO_END (__clone)
|
|
|
|
weak_alias (__clone, clone)
|