mirror of
https://sourceware.org/git/glibc.git
synced 2025-11-03 20:53:13 +03:00
a5392bed09
2003-04-05 Roland McGrath <roland@redhat.com> * sysdeps/unix/sysv/linux/i386/setcontext.S: Rewrite to avoid writing below the stack pointer even if switching to the same context we are running right now. * catgets/gencat.c (read_input_file): Make sure that \n is not alone on the line before testing for continuation. * math/test-tgmath.c (compile_test): Initialize c.
83 lines
2.4 KiB
ArmAsm
83 lines
2.4 KiB
ArmAsm
/* Install given context.
|
|
Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Ulrich Drepper <drepper@redhat.com>, 2001.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
#include "ucontext_i.h"
|
|
|
|
|
|
ENTRY(__setcontext)
|
|
/* Load address of the context data structure. */
|
|
movl 4(%esp), %eax
|
|
|
|
/* Get the current signal mask. Note that we preserve EBX in case
|
|
the system call fails and we return from the function with an
|
|
error. */
|
|
pushl %ebx
|
|
xorl %edx, %edx
|
|
leal oSIGMASK(%eax), %ecx
|
|
movl $SIG_SETMASK, %ebx
|
|
movl $__NR_sigprocmask, %eax
|
|
ENTER_KERNEL
|
|
popl %ebx
|
|
cmpl $-4095, %eax /* Check %eax for error. */
|
|
jae SYSCALL_ERROR_LABEL /* Jump to error handler if error. */
|
|
|
|
/* EAX was modified, reload it. */
|
|
movl 4(%esp), %eax
|
|
|
|
/* Restore the floating-point context. Not the registers, only the
|
|
rest. */
|
|
movl oFPREGS(%eax), %ecx
|
|
fldenv (%ecx)
|
|
|
|
/* Restore the FS segment register. We don't touch the GS register
|
|
since it is used for threads. */
|
|
movl oFS(%eax), %ecx
|
|
movw %cx, %fs
|
|
|
|
/* Fetch the address to return to. */
|
|
movl oEIP(%eax), %ecx
|
|
|
|
/* Load the new stack pointer. */
|
|
movl oESP(%eax), %esp
|
|
|
|
/* Push the return address on the new stack so we can return there. */
|
|
pushl %ecx
|
|
|
|
/* Load the values of all the 32-bit registers (except ESP).
|
|
Since we are loading from EAX, it must be last. */
|
|
movl oEDI(%eax), %edi
|
|
movl oESI(%eax), %esi
|
|
movl oEBP(%eax), %ebp
|
|
movl oEBX(%eax), %ebx
|
|
movl oEDX(%eax), %edx
|
|
movl oECX(%eax), %ecx
|
|
movl oEAX(%eax), %eax
|
|
|
|
/* The following 'ret' will pop the address of the code and jump
|
|
to it. */
|
|
|
|
L(pseudo_end):
|
|
ret
|
|
PSEUDO_END(__setcontext)
|
|
|
|
weak_alias(__setcontext, setcontext)
|