mirror of
https://sourceware.org/git/glibc.git
synced 2025-10-30 10:45:40 +03:00
d8a5edc221
found. Reported by Alexandre Oliva <aoliva@redhat.com>. 2003-03-13 Alexandre Oliva <aoliva@redhat.com> * stdio-common/_itoa.c (_itoa_base_table): Make 64-bit literals long long. * stdlib/fpioconst.c: Likewise. * stdlib/strtod.c: Likewise. * sysdeps/mips/add_n.S: Use L macro for local labels. * sysdeps/mips/addmul_1.S: Likewise. * sysdeps/mips/lshift.S: Likewise. * sysdeps/mips/memcpy.S: Likewise. * sysdeps/mips/memset.S: Likewise. * sysdeps/mips/mul_1.S: Likewise. * sysdeps/mips/rshift.S: Likewise. * sysdeps/mips/sub_n.S: Likewise. * sysdeps/mips/submul_1.S: Likewise. * sysdeps/mips/mips64/add_n.S: Likewise. * sysdeps/mips/mips64/addmul_1.S: Likewise. * sysdeps/mips/mips64/lshift.S: Likewise. * sysdeps/mips/mips64/mul_1.S: Likewise. * sysdeps/mips/mips64/rshift.S: Likewise. * sysdeps/mips/mips64/sub_n.S: Likewise. * sysdeps/mips/mips64/submul_1.S: Likewise. * sysdeps/unix/mips/sysdep.h: Define L() according to ABI conventions. Define END as in sys/asm.h. * sysdeps/unix/mips/sysdep.S: Likewise. * sysdeps/unix/mips/wait.S: Likewise. * sysdeps/unix/sysv/linux/mips/clone.S: Likewise. * sysdeps/ieee754/dbl-64/dbl2mpn.c (__mpn_extract_double): Cast shifted values that may be too narrow to mp_limb_t. * sysdeps/ieee754/dbl-64/mpn2dbl.c (__mpn_construct_double): Likewise. * sysdeps/ieee754/flt-32/mpn2flt.c (__mpn_construct_float): Likewise. * sysdeps/ieee754/ldbl-128/ldbl2mpn.c (__mpn_extract_long_double): Likewise. * sysdeps/ieee754/ldbl-128/mpn2ldbl.c (__mpn_construct_long_double): Likewise. * sysdeps/ieee754/ldbl-96/ldbl2mpn.c (__mpn_extract_long_double): Likewise. * sysdeps/ieee754/ldbl-96/mpn2ldbl.c (__mpn_construct_long_double): Likewise. 2003-03-13 Roland McGrath <roland@redhat.com>
99 lines
2.0 KiB
ArmAsm
99 lines
2.0 KiB
ArmAsm
/* MIPS2 __mpn_lshift --
|
|
|
|
Copyright (C) 1995, 2000, 2002, 2003 Free Software Foundation, Inc.
|
|
|
|
This file is part of the GNU MP Library.
|
|
|
|
The GNU MP Library is free software; you can redistribute it and/or modify
|
|
it under the terms of the GNU Lesser General Public License as published by
|
|
the Free Software Foundation; either version 2.1 of the License, or (at your
|
|
option) any later version.
|
|
|
|
The GNU MP Library is distributed in the hope that it will be useful, but
|
|
WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
|
|
License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public License
|
|
along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
|
|
MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
/* INPUT PARAMETERS
|
|
res_ptr $4
|
|
src_ptr $5
|
|
size $6
|
|
cnt $7
|
|
*/
|
|
#ifdef __PIC__
|
|
.option pic2
|
|
#endif
|
|
ENTRY (__mpn_lshift)
|
|
.set noreorder
|
|
#ifdef __PIC__
|
|
.cpload t9
|
|
#endif
|
|
.set nomacro
|
|
|
|
sll $2,$6,2
|
|
addu $5,$5,$2 /* make r5 point at end of src */
|
|
lw $10,-4($5) /* load first limb */
|
|
subu $13,$0,$7
|
|
addu $4,$4,$2 /* make r4 point at end of res */
|
|
addiu $6,$6,-1
|
|
and $9,$6,4-1 /* number of limbs in first loop */
|
|
beq $9,$0,L(L0) /* if multiple of 4 limbs, skip first loop */
|
|
srl $2,$10,$13 /* compute function result */
|
|
|
|
subu $6,$6,$9
|
|
|
|
L(Loop0): lw $3,-8($5)
|
|
addiu $4,$4,-4
|
|
addiu $5,$5,-4
|
|
addiu $9,$9,-1
|
|
sll $11,$10,$7
|
|
srl $12,$3,$13
|
|
move $10,$3
|
|
or $8,$11,$12
|
|
bne $9,$0,L(Loop0)
|
|
sw $8,0($4)
|
|
|
|
L(L0): beq $6,$0,L(Lend)
|
|
nop
|
|
|
|
L(Loop): lw $3,-8($5)
|
|
addiu $4,$4,-16
|
|
addiu $6,$6,-4
|
|
sll $11,$10,$7
|
|
srl $12,$3,$13
|
|
|
|
lw $10,-12($5)
|
|
sll $14,$3,$7
|
|
or $8,$11,$12
|
|
sw $8,12($4)
|
|
srl $9,$10,$13
|
|
|
|
lw $3,-16($5)
|
|
sll $11,$10,$7
|
|
or $8,$14,$9
|
|
sw $8,8($4)
|
|
srl $12,$3,$13
|
|
|
|
lw $10,-20($5)
|
|
sll $14,$3,$7
|
|
or $8,$11,$12
|
|
sw $8,4($4)
|
|
srl $9,$10,$13
|
|
|
|
addiu $5,$5,-16
|
|
or $8,$14,$9
|
|
bgtz $6,L(Loop)
|
|
sw $8,0($4)
|
|
|
|
L(Lend): sll $8,$10,$7
|
|
j $31
|
|
sw $8,-4($4)
|
|
END (__mpn_lshift)
|