mirror of
https://sourceware.org/git/glibc.git
synced 2025-10-30 10:45:40 +03:00
ee63ca212c
* sysdeps/unix/i386/sysdep.S (syscall_error): Push & pop space for BP return value & push implicit struct-return pointer to __errno_location. * sysdeps/unix/sysv/linux/i386/sysdep.h: Likewise. (SYSCALL_ERROR_HANDLER): Likewise. * sysdeps/unix/sysv/linux/i386/i686/sysdep.h (SYSCALL_ERROR_HANDLER): Likewise. * sysdeps/i386/bp-asm.h (POP_ERRNO_LOCATION_RETURN): Fold insns. * sysdeps/unix/i386/sysdep.S (syscall_error): Push & pop space for BP return value & push implicit struct-return pointer to __errno_location. * sysdeps/unix/sysv/linux/i386/sysdep.h: Likewise. (SYSCALL_ERROR_HANDLER): Likewise. * sysdeps/unix/sysv/linux/i386/i686/sysdep.h (SYSCALL_ERROR_HANDLER): Likewise. * Makeconfig (CPPFLAGS-.ob): Pass -fbounded-pointers for all files *.[cS].
79 lines
2.3 KiB
ArmAsm
79 lines
2.3 KiB
ArmAsm
/* Copyright (C) 1991, 92, 93, 94, 95, 96, 97, 2000 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H
|
|
#include <bits/errno.h>
|
|
#include <bp-asm.h>
|
|
#include <bp-sym.h>
|
|
|
|
.globl C_SYMBOL_NAME(errno)
|
|
.globl syscall_error
|
|
|
|
#undef syscall_error
|
|
#ifdef NO_UNDERSCORES
|
|
__syscall_error:
|
|
#else
|
|
syscall_error:
|
|
#endif
|
|
#if defined (EWOULDBLOCK_sys) && EWOULDBLOCK_sys != EAGAIN
|
|
/* We translate the system's EWOULDBLOCK error into EAGAIN.
|
|
The GNU C library always defines EWOULDBLOCK==EAGAIN.
|
|
EWOULDBLOCK_sys is the original number. */
|
|
cmpl $EWOULDBLOCK_sys, %eax /* Is it the old EWOULDBLOCK? */
|
|
jne notb /* Branch if not. */
|
|
movl $EAGAIN, %eax /* Yes; translate it to EAGAIN. */
|
|
notb:
|
|
#endif
|
|
#ifndef PIC
|
|
# ifndef _LIBC_REENTRANT
|
|
movl %eax, C_SYMBOL_NAME(errno)
|
|
# else
|
|
pushl %eax
|
|
PUSH_ERRNO_LOCATION_RETURN
|
|
call BP_SYM (__errno_location)
|
|
POP_ERRNO_LOCATION_RETURN
|
|
popl %ecx
|
|
movl %ecx, (%eax)
|
|
# endif
|
|
#else
|
|
/* The caller has pushed %ebx and then set it up to
|
|
point to the GOT before calling us through the PLT. */
|
|
# ifndef _LIBC_REENTRANT
|
|
movl C_SYMBOL_NAME(errno@GOT)(%ebx), %ecx
|
|
|
|
/* Pop %ebx value saved before jumping here. */
|
|
popl %ebx
|
|
movl %eax, (%ecx)
|
|
# else
|
|
pushl %eax
|
|
PUSH_ERRNO_LOCATION_RETURN
|
|
call C_SYMBOL_NAME (BP_SYM (__errno_location)@PLT)
|
|
POP_ERRNO_LOCATION_RETURN
|
|
popl %ecx
|
|
/* Pop %ebx value saved before jumping here. */
|
|
popl %ebx
|
|
movl %ecx, (%eax)
|
|
# endif
|
|
#endif
|
|
movl $-1, %eax
|
|
ret
|
|
|
|
#undef __syscall_error
|
|
END (__syscall_error)
|