mirror of
https://sourceware.org/git/glibc.git
synced 2025-10-30 10:45:40 +03:00
217eb19b6f
1999-10-11 Ulrich Drepper <drepper@cygnus.com> * sysdeps/powerpc/Makefile [math] (libm-support): Remove t_sqrt. * sysdeps/powerpc/e_sqrt.c: Moved to... * sysdeps/powerpc/fpu/e_sqrt.c: ...here. * sysdeps/powerpc/e_sqrtf.c: Moved to... * sysdeps/powerpc/fpu/e_sqrtf.c: ...here. * sysdeps/powerpc/submul_1.S: Adjust asm syntax. * sysdeps/powerpc/sub_n.S: Likewise. * sysdeps/powerpc/strlen.S: Likewise. * sysdeps/powerpc/strcpy.S: Likewise. * sysdeps/powerpc/strcmp.S: Likewise. * sysdeps/powerpc/strchr.S: Likewise. * sysdeps/powerpc/stpcpy.S: Likewise. * sysdeps/powerpc/setjmp.S: Likewise. * sysdeps/powerpc/rshift.S: Likewise. * sysdeps/powerpc/ppc-mcount.S: Likewise. * sysdeps/powerpc/mul_1.S: Likewise. * sysdeps/powerpc/memset.S: Likewise. * sysdeps/powerpc/lshift.S: Likewise. * sysdeps/powerpc/dl-start.S: Likewise. * sysdeps/powerpc/bzero.S: Likewise. * sysdeps/powerpc/bsd-setjmp.S: Likewise. * sysdeps/powerpc/bsd-_setjmp.S: Likewise. * sysdeps/powerpc/addmul_1.S: Likewise. * sysdeps/powerpc/add_n.S: Likewise. * sysdeps/powerpc/__longjmp.S: Likewise. * sysdeps/powerpc/elf/start.S: Likewise. 1999-10-11 Cristian Gafton <gafton@redhat.com> * sysdeps/unix/sysv/linux/alpha/bits/sigaction.h: Declare
101 lines
2.3 KiB
ArmAsm
101 lines
2.3 KiB
ArmAsm
/* Optimized stpcpy implementation for PowerPC.
|
|
Copyright (C) 1997, 1999 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
/* See strlen.s for comments on how the end-of-string testing works. */
|
|
|
|
EALIGN(__stpcpy,4,0)
|
|
/* char * [r3] stpcpy (char *dest [r3], const char *src [r4]) */
|
|
|
|
/* General register assignments:
|
|
r0: temporary
|
|
r3: pointer to previous word in dest
|
|
r4: pointer to previous word in src
|
|
r6: current word from src
|
|
r7: 0xfefefeff
|
|
r8: 0x7f7f7f7f
|
|
r9: ~(word in src | 0x7f7f7f7f)
|
|
r10: alternate word from src. */
|
|
|
|
or r0,r4,r3
|
|
clrlwi. r0,r0,30
|
|
addi r3,r3,-4
|
|
bne L(unaligned)
|
|
|
|
lis r7,0xfeff
|
|
lis r8,0x7f7f
|
|
lwz r6,0(r4)
|
|
addi r7,r7,-0x101
|
|
addi r8,r8,0x7f7f
|
|
b 2f
|
|
|
|
0: lwzu r10,4(r4)
|
|
stwu r6,4(r3)
|
|
add r0,r7,r10
|
|
nor r9,r8,r10
|
|
and. r0,r0,r9
|
|
bne- 1f
|
|
lwzu r6,4(r4)
|
|
stwu r10,4(r3)
|
|
2: add r0,r7,r6
|
|
nor r9,r8,r6
|
|
and. r0,r0,r9
|
|
beq+ 0b
|
|
|
|
mr r10,r6
|
|
/* We've hit the end of the string. Do the rest byte-by-byte. */
|
|
1: rlwinm. r0,r10,8,24,31
|
|
stbu r0,4(r3)
|
|
beqlr-
|
|
rlwinm. r0,r10,16,24,31
|
|
stbu r0,1(r3)
|
|
beqlr-
|
|
rlwinm. r0,r10,24,24,31
|
|
stbu r0,1(r3)
|
|
beqlr-
|
|
stbu r10,1(r3)
|
|
blr
|
|
|
|
/* Oh well. In this case, we just do a byte-by-byte copy. */
|
|
.align 4
|
|
nop
|
|
L(unaligned):
|
|
lbz r6,0(r4)
|
|
addi r3,r3,3
|
|
cmpwi r6,0
|
|
beq- 2f
|
|
|
|
0: lbzu r10,1(r4)
|
|
stbu r6,1(r3)
|
|
cmpwi r10,0
|
|
beq- 1f
|
|
nop /* Let 601 load start of loop. */
|
|
lbzu r6,1(r4)
|
|
stbu r10,1(r3)
|
|
cmpwi r6,0
|
|
bne+ 0b
|
|
2: stbu r6,1(r3)
|
|
blr
|
|
1: stbu r10,1(r3)
|
|
blr
|
|
END(__stpcpy)
|
|
|
|
weak_alias (__stpcpy, stpcpy)
|