mirror of
https://sourceware.org/git/glibc.git
synced 2025-10-30 10:45:40 +03:00
cb8a6dbd17
Autoconf has been deprecating configure.in for quite a long time. Rename all our configure.in and preconfigure.in files to .ac. Signed-off-by: Mike Frysinger <vapier@gentoo.org>
38 lines
1.4 KiB
Plaintext
38 lines
1.4 KiB
Plaintext
sinclude(./aclocal.m4)dnl Autoconf lossage
|
|
GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
|
|
# Local configure fragment for sysdeps/unix/sysv/linux/powerpc/.
|
|
|
|
AC_CACHE_CHECK(whether $CC $CFLAGS -mlong-double-128 uses IBM extended format,
|
|
libc_cv_mlong_double_128ibm, [dnl
|
|
save_CFLAGS="$CFLAGS"
|
|
CFLAGS="$CFLAGS -mlong-double-128"
|
|
AC_TRY_COMPILE([#include <float.h>], [
|
|
#if LDBL_MANT_DIG != 106
|
|
# error "compiler doesn't implement IBM extended format of long double"
|
|
#endif
|
|
long double foobar (long double x) { return x; }],
|
|
libc_cv_mlong_double_128ibm=yes,
|
|
libc_cv_mlong_double_128ibm=no)
|
|
CFLAGS="$save_CFLAGS"])
|
|
|
|
if test "$libc_cv_mlong_double_128ibm" = no; then
|
|
AC_CACHE_CHECK(whether $CC $CFLAGS supports -mabi=ibmlongdouble,
|
|
libc_cv_mabi_ibmlongdouble, [dnl
|
|
save_CFLAGS="$CFLAGS"
|
|
CFLAGS="$CFLAGS -mlong-double-128 -mabi=ibmlongdouble"
|
|
AC_TRY_COMPILE([#include <float.h>], [
|
|
#if LDBL_MANT_DIG != 106
|
|
# error "compiler doesn't implement IBM extended format of long double"
|
|
#endif
|
|
long double foobar (long double x) { return x; }],
|
|
libc_cv_mabi_ibmlongdouble=yes,
|
|
libc_cv_mabi_ibmlongdouble=no)
|
|
CFLAGS="$save_CFLAGS"])
|
|
|
|
if test "$libc_cv_mabi_ibmlongdouble" = yes; then
|
|
CFLAGS="$CFLAGS -mabi=ibmlongdouble"
|
|
else
|
|
AC_MSG_ERROR([this configuration requires -mlong-double-128 IBM extended format support])
|
|
fi
|
|
fi
|