mirror of
https://sourceware.org/git/glibc.git
synced 2025-11-03 20:53:13 +03:00
656dd306d4
Fix a: .../sysdeps/unix/sysv/linux/riscv/configure: line 181: test: =: unary operator expected message produced by the RISC-V configure fragment with the soft-float ABI selected, caused by $libc_cv_riscv_float_abi evaluating to nil in the invocation of `test $libc_cv_riscv_float_abi = no'. * sysdeps/unix/sysv/linux/riscv/configure.ac: Quote $libc_cv_riscv_float_abi in `test' invocation. * sysdeps/unix/sysv/linux/riscv/configure: Regenerate.
39 lines
1.1 KiB
Plaintext
39 lines
1.1 KiB
Plaintext
sinclude(./aclocal.m4)dnl Autoconf lossage
|
|
GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
|
|
# Local configure fragment for sysdeps/unix/sysv/linux/riscv.
|
|
|
|
arch_minimum_kernel=4.15.0
|
|
|
|
libc_cv_riscv_int_abi=no
|
|
AC_EGREP_CPP(4 8 8, [__SIZEOF_INT__ __SIZEOF_LONG__ __SIZEOF_POINTER__
|
|
], libc_cv_riscv_int_abi=lp64)
|
|
if test $libc_cv_riscv_int_abi = no; then
|
|
AC_MSG_ERROR([Unable to determine integer ABI])
|
|
fi
|
|
|
|
libc_cv_riscv_float_abi=no
|
|
AC_EGREP_CPP(yes, [#ifdef __riscv_float_abi_double
|
|
yes
|
|
#endif
|
|
],libc_cv_riscv_float_abi=d)
|
|
AC_EGREP_CPP(yes, [#ifdef __riscv_float_abi_soft
|
|
yes
|
|
#endif
|
|
],libc_cv_riscv_float_abi=)
|
|
if test "$libc_cv_riscv_float_abi" = no; then
|
|
AC_MSG_ERROR([Unable to determine floating-point ABI])
|
|
fi
|
|
|
|
LIBC_CONFIG_VAR([default-abi], [$libc_cv_riscv_int_abi$libc_cv_riscv_float_abi])
|
|
|
|
case $libc_cv_riscv_int_abi$libc_cv_riscv_float_abi-$machine in
|
|
lp64-riscv/rv64/*)
|
|
LIBC_SLIBDIR_RTLDDIR([lib64/lp64], [lib])
|
|
;;
|
|
lp64d-riscv/rv64/*)
|
|
LIBC_SLIBDIR_RTLDDIR([lib64/lp64d], [lib])
|
|
;;
|
|
esac
|
|
|
|
ldd_rewrite_script=sysdeps/unix/sysv/linux/riscv/ldd-rewrite.sed
|