mirror of
https://github.com/esp8266/Arduino.git
synced 2025-04-21 10:26:06 +03:00
a8e35a579c
Run valgrind on host mock example runs to catch more bugs in CI. These tests would have caught the problem in #7464 before users did. Add a list of some randomly picked examples to run, and add an option to run the loop exactly once in the host mock routine, so the test will actually exit under valgrind.
97 lines
2.3 KiB
C++
97 lines
2.3 KiB
C++
/*
|
|
This sketch establishes a TCP connection to a "quote of the day" service.
|
|
It sends a "hello" message, and then prints received data.
|
|
*/
|
|
|
|
#include <ESP8266WiFi.h>
|
|
|
|
#ifndef STASSID
|
|
#define STASSID "your-ssid"
|
|
#define STAPSK "your-password"
|
|
#endif
|
|
|
|
const char* ssid = STASSID;
|
|
const char* password = STAPSK;
|
|
|
|
const char* host = "djxmmx.net";
|
|
const uint16_t port = 17;
|
|
|
|
void setup() {
|
|
Serial.begin(115200);
|
|
|
|
// We start by connecting to a WiFi network
|
|
|
|
Serial.println();
|
|
Serial.println();
|
|
Serial.print("Connecting to ");
|
|
Serial.println(ssid);
|
|
|
|
/* Explicitly set the ESP8266 to be a WiFi-client, otherwise, it by default,
|
|
would try to act as both a client and an access-point and could cause
|
|
network-issues with your other WiFi-devices on your WiFi-network. */
|
|
WiFi.mode(WIFI_STA);
|
|
WiFi.begin(ssid, password);
|
|
|
|
while (WiFi.status() != WL_CONNECTED) {
|
|
delay(500);
|
|
Serial.print(".");
|
|
}
|
|
|
|
Serial.println("");
|
|
Serial.println("WiFi connected");
|
|
Serial.println("IP address: ");
|
|
Serial.println(WiFi.localIP());
|
|
}
|
|
|
|
void loop() {
|
|
static bool wait = false;
|
|
|
|
Serial.print("connecting to ");
|
|
Serial.print(host);
|
|
Serial.print(':');
|
|
Serial.println(port);
|
|
|
|
// Use WiFiClient class to create TCP connections
|
|
WiFiClient client;
|
|
if (!client.connect(host, port)) {
|
|
Serial.println("connection failed");
|
|
delay(5000);
|
|
return;
|
|
}
|
|
|
|
// This will send a string to the server
|
|
Serial.println("sending data to server");
|
|
if (client.connected()) {
|
|
client.println("hello from ESP8266");
|
|
}
|
|
|
|
// wait for data to be available
|
|
unsigned long timeout = millis();
|
|
while (client.available() == 0) {
|
|
if (millis() - timeout > 5000) {
|
|
Serial.println(">>> Client Timeout !");
|
|
client.stop();
|
|
delay(60000);
|
|
return;
|
|
}
|
|
}
|
|
|
|
// Read all the lines of the reply from server and print them to Serial
|
|
Serial.println("receiving from remote server");
|
|
// not testing 'client.connected()' since we do not need to send data here
|
|
while (client.available()) {
|
|
char ch = static_cast<char>(client.read());
|
|
Serial.print(ch);
|
|
}
|
|
|
|
// Close the connection
|
|
Serial.println();
|
|
Serial.println("closing connection");
|
|
client.stop();
|
|
|
|
if (wait) {
|
|
delay(300000); // execute once every 5 minutes, don't flood remote service
|
|
}
|
|
wait = true;
|
|
}
|