First integration of the Arduino code in Processing 5503: PreProcessor and Compiler have been integrated with changes to the Sketch.

Compilation still has problems (Thread error on success, and can't handle non-pde files in a sketch).
Modified the Mac OS X make.sh to copy the hardware, avr tools, and example over.
Removing some of the antlr stuff.  
Disabling the Commander (command-line execution) for now.
Added Library, LibraryManager, and Target.
Added support for prefixed preferences (e.g. for boards and programmers).

build/shared/examples/Digital/Blink/Blink.pde

@@ -0,0 +1,25 @@
+/*
+ * Blink
+ *
+ * The basic Arduino example.  Turns on an LED on for one second,
+ * then off for one second, and so on...  We use pin 13 because,
+ * depending on your Arduino board, it has either a built-in LED
+ * or a built-in resistor so that you need only an LED.
+ *
+ * http://www.arduino.cc/en/Tutorial/Blink
+ */
+
+int ledPin = 13;                // LED connected to digital pin 13
+
+void setup()                    // run once, when the sketch starts
+{
+  pinMode(ledPin, OUTPUT);      // sets the digital pin as output
+}
+
+void loop()                     // run over and over again
+{
+  digitalWrite(ledPin, HIGH);   // sets the LED on
+  delay(1000);                  // waits for a second
+  digitalWrite(ledPin, LOW);    // sets the LED off
+  delay(1000);                  // waits for a second
+}

build/shared/examples/Digital/BlinkWithoutDelay/BlinkWithoutDelay.pde

@@ -0,0 +1,38 @@
+/* Blink without Delay
+ *
+ * Turns on and off a light emitting diode(LED) connected to a digital  
+ * pin, without using the delay() function.  This means that other code
+ * can run at the same time without being interrupted by the LED code.
+ *
+ * http://www.arduino.cc/en/Tutorial/BlinkWithoutDelay
+ */
+
+int ledPin = 13;                // LED connected to digital pin 13
+int value = LOW;                // previous value of the LED
+long previousMillis = 0;        // will store last time LED was updated
+long interval = 1000;           // interval at which to blink (milliseconds)
+
+void setup()
+{
+  pinMode(ledPin, OUTPUT);      // sets the digital pin as output
+}
+
+void loop()
+{
+  // here is where you'd put code that needs to be running all the time.
+
+  // check to see if it's time to blink the LED; that is, is the difference
+  // between the current time and last time we blinked the LED bigger than
+  // the interval at which we want to blink the LED.
+  if (millis() - previousMillis > interval) {
+    previousMillis = millis();   // remember the last time we blinked the LED
+
+    // if the LED is off turn it on and vice-versa.
+    if (value == LOW)
+      value = HIGH;
+    else
+      value = LOW;
+
+    digitalWrite(ledPin, value);
+  }
+}

build/shared/examples/Digital/Button/Button.pde

@@ -0,0 +1,27 @@
+/*
+ * Button
+ * by DojoDave <http://www.0j0.org>
+ *
+ * Turns on and off a light emitting diode(LED) connected to digital  
+ * pin 13, when pressing a pushbutton attached to pin 7. 
+ *
+ * http://www.arduino.cc/en/Tutorial/Button
+ */
+ 
+int ledPin = 13;                // choose the pin for the LED
+int inputPin = 2;               // choose the input pin (for a pushbutton)
+int val = 0;                    // variable for reading the pin status
+
+void setup() {
+  pinMode(ledPin, OUTPUT);      // declare LED as output
+  pinMode(inputPin, INPUT);     // declare pushbutton as input
+}
+
+void loop(){
+  val = digitalRead(inputPin);  // read input value
+  if (val == HIGH) {            // check if the input is HIGH
+    digitalWrite(ledPin, LOW);  // turn LED OFF
+  } else {
+    digitalWrite(ledPin, HIGH); // turn LED ON
+  }
+}

build/shared/examples/Digital/Debounce/Debounce.pde

@@ -0,0 +1,52 @@
+/* Debounce
+ * 
+ * Each time the input pin goes from LOW to HIGH (e.g. because of a push-button
+ * press), the output pin is toggled from LOW to HIGH or HIGH to LOW.  There's
+ * a minimum delay between toggles to debounce the circuit (i.e. to ignore
+ * noise).  
+ *
+ * David A. Mellis
+ * 21 November 2006
+ *
+ * http://www.arduino.cc/en/Tutorial/Debounce
+ */
+
+int inPin = 7;         // the number of the input pin
+int outPin = 13;       // the number of the output pin
+
+int state = HIGH;      // the current state of the output pin
+int reading;           // the current reading from the input pin
+int previous = LOW;    // the previous reading from the input pin
+
+// the follow variables are long's because the time, measured in miliseconds,
+// will quickly become a bigger number than can be stored in an int.
+long time = 0;         // the last time the output pin was toggled
+long debounce = 200;   // the debounce time, increase if the output flickers
+
+void setup()
+{
+  pinMode(inPin, INPUT);
+  pinMode(outPin, OUTPUT);
+}
+
+void loop()
+{
+  reading = digitalRead(inPin);
+
+  // if we just pressed the button (i.e. the input went from LOW to HIGH),
+  // and we've waited long enough since the last press to ignore any noise...  
+  if (reading == HIGH && previous == LOW && millis() - time > debounce) {
+    // ... invert the output
+    if (state == HIGH)
+      state = LOW;
+    else
+      state = HIGH;
+
+    // ... and remember when the last button press was
+    time = millis();    
+  }
+
+  digitalWrite(outPin, state);
+
+  previous = reading;
+}

build/shared/examples/Digital/Loop/Loop.pde

@@ -0,0 +1,37 @@
+/*
+ * Loop
+ * by David A. Mellis
+ *
+ * Lights multiple LEDs in sequence, then in reverse.  Demonstrates
+ * the use of a for() loop and arrays.
+ *
+ * http://www.arduino.cc/en/Tutorial/Loop
+ */
+
+int timer = 100;                   // The higher the number, the slower the timing.
+int pins[] = { 2, 3, 4, 5, 6, 7 }; // an array of pin numbers
+int num_pins = 6;                  // the number of pins (i.e. the length of the array)
+
+void setup()
+{
+  int i;
+
+  for (i = 0; i < num_pins; i++)   // the array elements are numbered from 0 to num_pins - 1
+    pinMode(pins[i], OUTPUT);      // set each pin as an output
+}
+
+void loop()
+{
+  int i;
+  
+  for (i = 0; i < num_pins; i++) { // loop through each pin...
+    digitalWrite(pins[i], HIGH);   // turning it on,
+    delay(timer);                  // pausing,
+    digitalWrite(pins[i], LOW);    // and turning it off.
+  }
+  for (i = num_pins - 1; i >= 0; i--) { 
+    digitalWrite(pins[i], HIGH);
+    delay(timer);
+    digitalWrite(pins[i], LOW);
+  }
+}

build/shared/examples/Digital/Melody/Melody.pde

@@ -0,0 +1,71 @@
+/* Melody
+ * (cleft) 2005 D. Cuartielles for K3
+ *
+ * This example uses a piezo speaker to play melodies.  It sends
+ * a square wave of the appropriate frequency to the piezo, generating
+ * the corresponding tone.
+ *
+ * The calculation of the tones is made following the mathematical
+ * operation:
+ *
+ *       timeHigh = period / 2 = 1 / (2 * toneFrequency)
+ *
+ * where the different tones are described as in the table:
+ *
+ * note 	frequency 	period 	timeHigh
+ * c 	        261 Hz 	        3830 	1915 	
+ * d 	        294 Hz 	        3400 	1700 	
+ * e 	        329 Hz 	        3038 	1519 	
+ * f 	        349 Hz 	        2864 	1432 	
+ * g 	        392 Hz 	        2550 	1275 	
+ * a 	        440 Hz 	        2272 	1136 	
+ * b 	        493 Hz 	        2028	1014	
+ * C	        523 Hz	        1912 	956
+ *
+ * http://www.arduino.cc/en/Tutorial/Melody
+ */
+  
+int speakerPin = 9;
+
+int length = 15; // the number of notes
+char notes[] = "ccggaagffeeddc "; // a space represents a rest
+int beats[] = { 1, 1, 1, 1, 1, 1, 2, 1, 1, 1, 1, 1, 1, 2, 4 };
+int tempo = 300;
+
+void playTone(int tone, int duration) {
+  for (long i = 0; i < duration * 1000L; i += tone * 2) {
+    digitalWrite(speakerPin, HIGH);
+    delayMicroseconds(tone);
+    digitalWrite(speakerPin, LOW);
+    delayMicroseconds(tone);
+  }
+}
+
+void playNote(char note, int duration) {
+  char names[] = { 'c', 'd', 'e', 'f', 'g', 'a', 'b', 'C' };
+  int tones[] = { 1915, 1700, 1519, 1432, 1275, 1136, 1014, 956 };
+  
+  // play the tone corresponding to the note name
+  for (int i = 0; i < 8; i++) {
+    if (names[i] == note) {
+      playTone(tones[i], duration);
+    }
+  }
+}
+
+void setup() {
+  pinMode(speakerPin, OUTPUT);
+}
+
+void loop() {
+  for (int i = 0; i < length; i++) {
+    if (notes[i] == ' ') {
+      delay(beats[i] * tempo); // rest
+    } else {
+      playNote(notes[i], beats[i] * tempo);
+    }
+    
+    // pause between notes
+    delay(tempo / 2); 
+  }
+}