Cleanup and prepare for publishing.

examples/mqtt_esp8266/mqtt_esp8266.ino

@@ -0,0 +1,136 @@
+/*************************************************** 
+  Adafruit MQTT Library ESP8266 Example
+
+  Must use ESP8266 Arduino from:
+    https://github.com/esp8266/Arduino
+
+  Works great with Adafruit's Huzzah ESP board:
+  ----> https://www.adafruit.com/product/2471
+
+  Adafruit invests time and resources providing this open source code, 
+  please support Adafruit and open-source hardware by purchasing 
+  products from Adafruit!
+
+  Written by Tony DiCola for Adafruit Industries.  
+  MIT license, all text above must be included in any redistribution
+ ****************************************************/
+#include <ESP8266WiFi.h>
+#include "Adafruit_MQTT.h"
+#include "Adafruit_MQTT_Client.h"
+
+/************************* WiFi Access Point *********************************/
+
+#define WLAN_SSID       "...your SSID..."
+#define WLAN_PASS       "...your password..."
+
+/************************* Adafruit.io Setup *********************************/
+
+#define AIO_SERVER      "io.adafruit.com"
+#define AIO_SERVERPORT  1883
+#define AIO_USERNAME    "...your AIO username (see https://accounts.adafruit.com)..."
+#define AIO_KEY         "...your AIO key...";
+
+/************ Global State (you don't need to change this!) ******************/
+
+// Create an ESP8266 WiFiClient class to connect to the MQTT server.
+WiFiClient client;
+
+// Store the MQTT server, client ID, username, and password in flash memory.
+// This is required for using the Adafruit MQTT library.
+const char MQTT_SERVER[] PROGMEM    = AIO_SERVER;
+const char MQTT_CLIENTID[] PROGMEM  = AIO_KEY;
+const char MQTT_USERNAME[] PROGMEM  = AIO_USERNAME;
+const char MQTT_PASSWORD[] PROGMEM  = AIO_KEY;
+
+// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
+Adafruit_MQTT_Client mqtt(&client, MQTT_SERVER, AIO_SERVERPORT, MQTT_CLIENTID, MQTT_USERNAME, MQTT_PASSWORD);
+
+/****************************** Feeds ***************************************/
+
+// Setup a feed called 'photocell' for publishing.  
+// Notice MQTT paths for AIO follow the form: <username>/feeds/<feedname>
+const char PHOTOCELL_FEED[] PROGMEM = AIO_USERNAME "/feeds/photocell";
+Adafruit_MQTT_Publish photocell = Adafruit_MQTT_Publish(&mqtt, PHOTOCELL_FEED);
+
+// Setup a feed called 'onoff' for subscribing to changes.  
+const char ONOFF_FEED[] PROGMEM = AIO_USERNAME "/feeds/onoff";
+Adafruit_MQTT_Subscribe onoffbutton = Adafruit_MQTT_Subscribe(&mqtt, ONOFF_FEED);
+
+/*************************** Sketch Code ************************************/
+
+void setup() {
+  Serial.begin(115200);
+  delay(10);
+
+  Serial.println(F("Adafruit MQTT demo"));
+
+  // Connect to WiFi access point.
+  Serial.println(); Serial.println();
+  Serial.print("Connecting to ");
+  Serial.println(WLAN_SSID);
+  
+  WiFi.begin(WLAN_SSID, WLAN_PASS);
+  while (WiFi.status() != WL_CONNECTED) {
+    delay(500);
+    Serial.print(".");
+  }
+  Serial.println();
+
+  Serial.println("WiFi connected");  
+  Serial.println("IP address: "); Serial.println(WiFi.localIP());
+
+  // Setup MQTT subscription for onoff feed.
+  mqtt.subscribe(&onoffbutton);
+
+  // Connect to MQTT server.
+  Serial.println(F("Connecting to MQTT..."));
+  int8_t ret;
+  while ((ret = mqtt.connect()) != 0) {
+       switch (ret) {
+          case 1: Serial.println(F("Wrong protocol")); break;
+          case 2: Serial.println(F("ID rejected")); break;
+          case 3: Serial.println(F("Server unavail")); break;
+          case 4: Serial.println(F("Bad user/pass")); break;
+          case 5: Serial.println(F("Not authed")); break;
+          case 6: Serial.println(F("Failed to subscribe")); break;
+          default: Serial.println(F("Couldn't connect to MQTT server")); break;
+       }
+       Serial.println(F("Retrying MQTT connection"));
+       mqtt.disconnect();
+       delay(5000); 
+  }
+  Serial.println(F("MQTT Connected!"));
+}
+
+uint32_t x=0;
+
+void loop() {
+  // Try to ping the MQTT server
+  /*
+  if (! mqtt.ping(3) ) {
+    // MQTT pings failed, lets reconnect
+    Serial.println("Ping fail!");
+  }
+  */
+
+  // this is our 'wait for incoming subscription packets' busy subloop
+  Adafruit_MQTT_Subscribe *subscription;
+  while (subscription = mqtt.readSubscription(1000)) {
+    if (subscription == &onoffbutton) {
+      Serial.print(F("Got: ")); 
+      Serial.println((char *)onoffbutton.lastread);
+    }
+  }
+  
+  // Now we can publish stuff!
+  Serial.print(F("\nSending photocell val ")); 
+  Serial.print(x);
+  Serial.print("...");
+  if (! photocell.publish(x++)) {
+    Serial.println(F("Failed"));
+  } else {
+    Serial.println(F("OK!"));
+  }
+
+  delay(1000);
+}